reserve x for object;
reserve x0,r,r1,r2,g,g1,g2,p,y0 for Real;
reserve n,m,k,l for Element of NAT;
reserve a,b,d for Real_Sequence;
reserve h,h1,h2 for non-zero 0-convergent Real_Sequence;
reserve c,c1 for constant Real_Sequence;
reserve A for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;
reserve L for LinearFunc;
reserve R for RestFunc;

theorem Th1:
  a is convergent & b is convergent & lim a = lim b & (for n holds
  d.(2*n) = a.n & d.(2*n + 1) = b.n) implies d is convergent & lim d = lim a
proof
  assume that
A1: a is convergent and
A2: b is convergent and
A3: lim a = lim b and
A4: for n holds d.(2*n) = a.n & d.(2*n+1) = b.n;
A5: now
    let r be Real;
    assume
A6: 0<r;
    then consider k1 be Nat such that
A7: for m being Nat st k1 <= m holds |.a.m - lim a.| < r by A1,SEQ_2:def 7;
    consider k2 be Nat such that
A8: for m being Nat st k2 <= m holds |.b.m - lim b.| < r
          by A2,A6,SEQ_2:def 7;
     reconsider n = max(2*k1,2*k2+1) as Nat by TARSKI:1;
    take n;
    let m be Nat;
    assume
A9: n<=m;
    then
A10: 2*k2 + 1 <= m by XXREAL_0:30;
    consider n being Element of NAT such that
A11: m = 2*n or m = 2*n + 1 by SCHEME1:1;
A12: 2*k1 <= m by A9,XXREAL_0:30;
    now
      per cases by A11;
      suppose
A13:    m = 2*n;
        then
A14:    n >= k1 by A12,XREAL_1:68;
        |.d.m - lim a.| = |.a.n - lim a.| by A4,A13;
        hence |.d.m - lim a.| < r by A7,A14;
      end;
      suppose
A15:    m = 2*n + 1;
A16:    now
          assume n < k2;
          then 2*n < 2*k2 by XREAL_1:68;
          hence contradiction by A10,A15,XREAL_1:6;
        end;
        |.d.m - lim a.| = |.b.n - lim a.| by A4,A15;
        hence |.d.m - lim a.| < r by A3,A8,A16;
      end;
    end;
    hence |.d.m - lim a.| < r;
  end;
  hence d is convergent by SEQ_2:def 6;
  hence thesis by A5,SEQ_2:def 7;
end;
