reserve h,h1,h2 for 0-convergent non-zero Real_Sequence,
  c,c1 for constant Real_Sequence,
  f,f1,f2 for PartFunc of REAL,REAL,
  x0,r,r0,r1,r2,g,g1,g2 for Real,
  n0,k,n,m for Element of NAT,
  a,b,d for Real_Sequence,
  x for set;

theorem Th1:
  (ex r st r>0 & [.x0-r,x0.] c= dom f) implies ex h,c st rng c ={x0
  } & rng (h+c) c= dom f & for n being Nat holds h.n < 0
proof
  given r such that
A1: r>0 and
A2: [.x0-r,x0.] c= dom f;
  reconsider xx0 = x0 as Element of REAL by XREAL_0:def 1;
  set a = seq_const x0;
  reconsider a as constant Real_Sequence;
  deffunc F(Nat) = (-r)/($1+2);
  consider b such that
A3: for n being Nat holds b.n = F(n) from SEQ_1:sch 1;
A4: now
    let n be Nat;
    0 < r/(n+2) by A1,XREAL_1:139;
    then -(r/(n+2)) < -0 by XREAL_1:24;
    then (-r)/(n+2) < 0 by XCMPLX_1:187;
    hence b.n < 0 by A3;
  end;
  then for n being Nat holds 0 <> b.n;
  then
A5: b is non-zero by SEQ_1:5;
  b is convergent & lim b = 0 by A3,SEQ_4:31;
  then reconsider b as 0-convergent non-zero Real_Sequence
    by A5,FDIFF_1:def 1;
  take b;
  take a;
  thus rng a = {x0}
  proof
    thus rng a c= {x0}
    proof
      let x be object;
      assume x in rng a;
      then ex n st x = a.n by FUNCT_2:113;
      then x = x0 by SEQ_1:57;
      hence thesis by TARSKI:def 1;
    end;
    let x be object;
    assume x in {x0};
    then x = x0 by TARSKI:def 1
      .= a.0 by SEQ_1:57;
    hence thesis by VALUED_0:28;
  end;
  thus rng (b+a) c= dom f
  proof
    let x be object;
    assume x in rng (b+a);
    then consider n such that
A6: x = (b+a).n by FUNCT_2:113;
 0+1 < n + 2 by XREAL_1:8;
    then r*1 < r*(n+2) by A1,XREAL_1:97;
    then r * (n+2)" < r*(n + 2)*((n + 2)") by XREAL_1:68;
    then r * ((n+2)") < r*((n + 2)*(n + 2)");
    then r * (n+2)" < r * 1 by XCMPLX_0:def 7;
    then r/(n+2) < r by XCMPLX_0:def 9;
    then x0 - r < x0 - r/(n+2) by XREAL_1:15;
    then x0 - r < x0 + - r/(n+2);
    then
A7: x0 - r <= x0 + (-r)/(n+2) by XCMPLX_1:187;
    0 < r/(n+2) by A1,XREAL_1:139;
    then x0 - r/(n+2) < x0 - 0 by XREAL_1:15;
    then x0 + - r/(n+2) <= x0;
    then x0 + (-r)/(n+2) <= x0 by XCMPLX_1:187;
    then
A8: x0 + (-r)/(n+2) in {g1: x0 - r <= g1 & g1 <= x0 } by A7;
    x = b.n +a.n by A6,SEQ_1:7
      .= (-r)/(n+2) + a.n by A3
      .= x0 + (-r)/(n+2) by SEQ_1:57;
    then x in [.x0 - r, x0.] by A8,RCOMP_1:def 1;
    hence thesis by A2;
  end;
  thus thesis by A4;
end;
