 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem Th1:
  Z c= dom (sec*((id Z)^)) implies (-sec*((id Z)^)) is_differentiable_on Z &
  for x st x in Z holds
  ((-sec*((id Z)^))`|Z).x = sin.(1/x)/(x^2*(cos.(1/x))^2)
proof
  assume
A1:Z c= dom (sec*((id Z)^));
then A2:Z c= dom (-sec*((id Z)^)) by VALUED_1:def 5;
A3:Z c= dom ((id Z)^) by A1,FUNCT_1:101;
A4:not 0 in Z
   proof
     assume A5: 0 in Z;
     dom ((id Z)^) = dom id Z \ (id Z)"{0} by RFUNCT_1:def 2
                  .= dom id Z \ {0} by Lm1,A5; then
     not 0 in {0} by A5,A3,XBOOLE_0:def 5;
     hence thesis by TARSKI:def 1;
   end;
then A6:(sec*((id Z)^)) is_differentiable_on Z by A1,FDIFF_9:8;
then A7:(-1)(#)(sec*((id Z)^)) is_differentiable_on Z by A2,FDIFF_1:20;
 for x st x in Z holds ((-sec*((id Z)^))`|Z).x = sin.(1/x)/(x^2*(cos.(1/x))^2)
  proof
   let x;
   assume
A8:x in Z;
  ((-sec*((id Z)^))`|Z).x=((-1)(#)((sec*((id Z)^))`|Z)).x by A6,FDIFF_2:19
                 .=(-1)*(((sec*((id Z)^))`|Z).x) by VALUED_1:6
                 .=(-1)*(-sin.(1/x)/(x^2*(cos.(1/x))^2)) by A1,A4,A8,FDIFF_9:8
                 .=sin.(1/x)/(x^2*(cos.(1/x))^2);
   hence thesis;
  end;
  hence thesis by A7;
end;
