
theorem Th1:
for f be PartFunc of REAL,REAL, a,b,c be Real
 st a <= b <= c & ['a,c'] c= dom f & f|['a,b'] is bounded &
 f|['b,c'] is bounded &
 f is_integrable_on ['a,b'] & f is_integrable_on ['b,c']
 holds f is_integrable_on ['a,c']
 & integral(f,a,c) = integral(f,a,b) + integral(f,b,c)
proof
    let f be PartFunc of REAL,REAL, a,b,c be Real;
    assume that
A1:  a <= b <= c and
A2:  ['a,c'] c= dom f and
A3:  f|['a,b'] is bounded and
A4:  f|['b,c'] is bounded and
A5:  f is_integrable_on ['a,b'] and
A6:  f is_integrable_on ['b,c'];

    thus
A7:  f is_integrable_on ['a,c']
    proof
     per cases;
     suppose A8: a <> b;
      per cases;
      suppose b <> c; then
       a < b < c by A1,A8,XXREAL_0:1;
       hence thesis by A2,A3,A4,A5,A6,Lm1;
      end;
      suppose b = c;
       hence thesis by A5;
      end;
     end;
     suppose a = b;
      hence thesis by A6;
     end;
    end;

A9: a <= c by A1,XXREAL_0:2;
A10: ['a,c'] = [.a,c.] by A1,XXREAL_0:2,INTEGRA5:def 3; then
A11: b in ['a,c'] by A1,XXREAL_1:1;

    ['a,b'] = [.a,b.] & ['b,c'] = [.b,c.] by A1,INTEGRA5:def 3; then
    ['a,c'] = ['a,b'] \/ ['b,c'] by A1,A10,XXREAL_1:165; then
    f|['a,c'] is bounded by A3,A4,RFUNCT_1:87;
    hence integral(f,a,c) = integral(f,a,b) + integral(f,b,c)
      by A2,A7,A9,A11,INTEGRA6:17;
end;
