reserve T,T1,T2,S for non empty TopSpace;

theorem Th1: :: BORSUK_2:1
  for f being Function of T1,S, g being Function of T2,S,F1,F2
being Subset of T st T1 is SubSpace of T & T2 is SubSpace of T & F1=[#] T1 & F2
  =[#] T2 & ([#] T1) \/ ([#] T2) = [#] T & F1 is closed & F2 is closed & f is
  continuous & g is continuous & (for p be object st p in ([#] T1) /\ ([#] T2)
  holds f.p = g.p ) ex h being Function of T,S st h = f+*g & h is continuous
proof
  let f be Function of T1,S, g be Function of T2,S,F1,F2 being Subset of T;
  assume that
A1: T1 is SubSpace of T and
A2: T2 is SubSpace of T and
A3: F1=[#] T1 and
A4: F2=[#] T2 and
A5: ([#] T1) \/ ([#] T2) = [#] T and
A6: F1 is closed and
A7: F2 is closed and
A8: f is continuous and
A9: g is continuous and
A10: for p be object st p in ([#] T1) /\ ([#] T2) holds f.p = g.p;
  set h = f+*g;
A11: dom g = the carrier of T2 by FUNCT_2:def 1
    .= [#] T2;
A12: dom f = the carrier of T1 by FUNCT_2:def 1
    .= [#] T1;
  then
A13: dom h = [#] T by A5,A11,FUNCT_4:def 1
    .= the carrier of T;
  rng h c= rng f \/ rng g by FUNCT_4:17;
  then reconsider h as Function of T,S by A13,FUNCT_2:2,XBOOLE_1:1;
  take h;
  thus h = f+*g;
  for P being Subset of S st P is closed holds h"P is closed
  proof
    let P be Subset of S;
    set P3 = f"P, P4 = g"P;
    [#] T1 c= [#] T by A5,XBOOLE_1:7;
    then reconsider P1 = f"P as Subset of T by XBOOLE_1:1;
    [#] T2 c= [#] T by A5,XBOOLE_1:7;
    then reconsider P2 = g"P as Subset of T by XBOOLE_1:1;
A14: dom h = dom f \/ dom g by FUNCT_4:def 1;
A15: now
      let x be object;
      thus x in h"P /\ [#] T2 implies x in g"P
      proof
        assume
A16:    x in h"P /\ [#] T2;
        then x in h"P by XBOOLE_0:def 4;
        then
A17:    h.x in P by FUNCT_1:def 7;
        g.x = h.x by A11,A16,FUNCT_4:13;
        hence thesis by A11,A16,A17,FUNCT_1:def 7;
      end;
      assume
A18:  x in g"P;
      then
A19:  x in dom g by FUNCT_1:def 7;
      g.x in P by A18,FUNCT_1:def 7;
      then
A20:  h.x in P by A19,FUNCT_4:13;
      x in dom h by A14,A19,XBOOLE_0:def 3;
      then x in h"P by A20,FUNCT_1:def 7;
      hence x in h"P /\ [#] T2 by A18,XBOOLE_0:def 4;
    end;
A21: for x being set st x in [#] T1 holds h.x = f.x
    proof
      let x be set such that
A22:  x in [#] T1;
      now
        per cases;
        suppose
A23:      x in [#] T2;
          then x in [#] T1 /\ [#] T2 by A22,XBOOLE_0:def 4;
          then f.x = g.x by A10;
          hence thesis by A11,A23,FUNCT_4:13;
        end;
        suppose
          not x in [#] T2;
          hence thesis by A11,FUNCT_4:11;
        end;
      end;
      hence thesis;
    end;
    now
      let x be object;
      thus x in h"P /\ [#] T1 implies x in f"P
      proof
        assume
A24:    x in h"P /\ [#] T1;
        then x in h"P by XBOOLE_0:def 4;
        then
A25:    h.x in P by FUNCT_1:def 7;
        f.x = h.x by A21,A24;
        hence thesis by A12,A24,A25,FUNCT_1:def 7;
      end;
      assume
A26:  x in f"P;
      then x in dom f by FUNCT_1:def 7;
      then
A27:  x in dom h by A14,XBOOLE_0:def 3;
      f.x in P by A26,FUNCT_1:def 7;
      then h.x in P by A21,A26;
      then x in h"P by A27,FUNCT_1:def 7;
      hence x in h"P /\ [#] T1 by A26,XBOOLE_0:def 4;
    end;
    then
A28: h"P /\ [#] T1 = f"P by TARSKI:2;
    assume
A29: P is closed;
    then P3 is closed by A8,PRE_TOPC:def 6;
    then ex F01 being Subset of T st F01 is closed & P3=F01 /\ [#] T1 by A1,
PRE_TOPC:13;
    then
A30: P1 is closed by A3,A6;
    P4 is closed by A9,A29,PRE_TOPC:def 6;
    then ex F02 being Subset of T st F02 is closed & P4=F02 /\ [#] T2 by A2,
PRE_TOPC:13;
    then
A31: P2 is closed by A4,A7;
    h"P = h"P /\ ([#] T1 \/ [#] T2) by A12,A11,A14,RELAT_1:132,XBOOLE_1:28
      .= (h"P /\ [#](T1)) \/ (h"P /\ [#](T2)) by XBOOLE_1:23;
    then h"P = f"P \/ g"P by A28,A15,TARSKI:2;
    hence thesis by A30,A31;
  end;
  hence thesis by PRE_TOPC:def 6;
end;
