reserve i,j,k,m,n for Nat,
  f for FinSequence of the carrier of TOP-REAL 2,
  G for Go-board;

theorem Th1:
  f is_sequence_on G & LSeg(G*(i,j),G*(i,k)) meets L~f & [i,j] in
Indices G & [i,k] in Indices G & j <= k implies ex n st j <= n & n <= k & G*(i,
  n)`2 = lower_bound(proj2.:(LSeg(G*(i,j),G*(i,k)) /\ L~f))
proof
  set X = LSeg(G*(i,j),G*(i,k)) /\ L~f;
  assume that
A1: f is_sequence_on G and
A2: LSeg(G*(i,j),G*(i,k)) meets L~f and
A3: [i,j] in Indices G and
A4: [i,k] in Indices G and
A5: j <= k;
A6: 1 <= i & i <= len G by A3,MATRIX_0:32;
  ex x being object st x in LSeg(G*(i,j),G*(i,k)) & x in L~f by A2,XBOOLE_0:3;
  then reconsider X1=X as non empty compact Subset of TOP-REAL 2
  by XBOOLE_0:def 4;
  consider p being object such that
A7: p in S-most X1 by XBOOLE_0:def 1;
  reconsider p as Point of TOP-REAL 2 by A7;
A8: p in X by A7,XBOOLE_0:def 4;
  then
A9: p in LSeg(G*(i,j),G*(i,k)) by XBOOLE_0:def 4;
  proj2.:X = (proj2|X).:X by RELAT_1:129;
  then
A10: lower_bound(proj2.:X) = lower_bound((proj2|X).: [#]((TOP-REAL 2)|X))
by PRE_TOPC:def 5
    .= S-bound X;
A11: 1 <= k by A4,MATRIX_0:32;
A12: p`2 = (S-min X)`2 by A7,PSCOMP_1:55
    .= lower_bound(proj2.:X) by A10,EUCLID:52;
A13: 1 <= i & i <= len G by A3,MATRIX_0:32;
A14: 1 <= j by A3,MATRIX_0:32;
A15: k <= width G by A4,MATRIX_0:32;
  then
A16: G*(i,j)`2 <= G*(i,k)`2 by A5,A6,A14,SPRECT_3:12;
  then
A17: G*(i,j)`2 <= p`2 by A9,TOPREAL1:4;
A18: p`2 <= G*(i,k)`2 by A9,A16,TOPREAL1:4;
A19: j <= width G by A3,MATRIX_0:32;
  then
A20: G*(i,j)`1 = G*(i,1)`1 by A6,A14,GOBOARD5:2
    .= G*(i,k)`1 by A13,A11,A15,GOBOARD5:2;
  p in L~f by A8,XBOOLE_0:def 4;
  then p in union { LSeg(f,k1) where k1 is Nat : 1 <= k1 & k1+1 <=
  len f} by TOPREAL1:def 4;
  then consider Y being set such that
A21: p in Y and
A22: Y in { LSeg(f,k1) where k1 is Nat : 1 <= k1 & k1+1 <=
  len f} by TARSKI:def 4;
  consider i1 being Nat such that
A23: Y = LSeg(f,i1) and
A24: 1 <= i1 and
A25: i1+1 <= len f by A22;
A26: p in LSeg(f/.i1,f/.(i1+1)) by A21,A23,A24,A25,TOPREAL1:def 3;
  1 < i1+1 by A24,NAT_1:13;
  then i1+1 in Seg len f by A25,FINSEQ_1:1;
  then
A27: i1+1 in dom f by FINSEQ_1:def 3;
  then consider io,jo being Nat such that
A28: [io,jo] in Indices G and
A29: f/.(i1+1) = G*(io,jo) by A1,GOBOARD1:def 9;
A30: 1 <= io & io <= len G by A28,MATRIX_0:32;
A31: 1 <= jo by A28,MATRIX_0:32;
  i1 <= len f by A25,NAT_1:13;
  then i1 in Seg len f by A24,FINSEQ_1:1;
  then
A32: i1 in dom f by FINSEQ_1:def 3;
  then consider i0,j0 being Nat such that
A33: [i0,j0] in Indices G and
A34: f/.i1 = G*(i0,j0) by A1,GOBOARD1:def 9;
A35: 1 <= i0 & i0 <= len G by A33,MATRIX_0:32;
A36: 1 <= j0 by A33,MATRIX_0:32;
A37: j0 <= width G by A33,MATRIX_0:32;
A38: jo <= width G by A28,MATRIX_0:32;
A39: f is special by A1,A32,JORDAN8:4,RELAT_1:38;
  ex n st j <= n & n <= k & G*(i,n) = p
  proof
    per cases by A24,A25,A39,TOPREAL1:def 5;
    suppose
A40:  (f/.i1)`1 = (f/.(i1+1))`1;
      G*(io,j)`1 = G*(io,1)`1 by A14,A19,A30,GOBOARD5:2
        .= G*(io,jo)`1 by A30,A31,A38,GOBOARD5:2
        .= p`1 by A26,A29,A40,GOBOARD7:5
        .= G*(i,j)`1 by A20,A9,GOBOARD7:5;
      then
  io<=i & io>=i by A6,A14,A19,A30,GOBOARD5:3;
      then
A41:  i=io by XXREAL_0:1;
      G*(i0,j)`1 = G*(i0,1)`1 by A14,A19,A35,GOBOARD5:2
        .= G*(i0,j0)`1 by A35,A36,A37,GOBOARD5:2
        .= p`1 by A26,A34,A40,GOBOARD7:5
        .= G*(i,j)`1 by A20,A9,GOBOARD7:5;
      then
  i0<=i & i0>=i by A6,A14,A19,A35,GOBOARD5:3;
      then
A42:  i=i0 by XXREAL_0:1;
      thus thesis
      proof
        per cases;
        suppose
A43:      (f/.i1)`2 <= (f/.(i1+1))`2;
          thus thesis
          proof
            per cases;
            suppose
A44:          (f/.i1) in LSeg(G*(i,j),G*(i,k));
              1+1<=i1+1 by A24,XREAL_1:6;
              then f/.i1 in L~f by A25,A32,GOBOARD1:1,XXREAL_0:2;
              then f/.i1 in X1 by A44,XBOOLE_0:def 4;
              then
A45:          p`2 <= (f/.i1)`2 by A10,A12,PSCOMP_1:24;
              take n=j0;
A46:          p in LSeg(G*(i,j),G*(i,k)) by A8,XBOOLE_0:def 4;
              p`2 >= (f/.i1)`2 by A26,A43,TOPREAL1:4;
              then p`2 = (f/.i1)`2 by A45,XXREAL_0:1;
              then
A47:          p`2 = G*(1,j0)`2 by A34,A35,A36,A37,GOBOARD5:1
                .= G*(i,n)`2 by A6,A36,A37,GOBOARD5:1;
A48:          G*(i,j)`2 <= G*(i,k)`2 by A5,A6,A14,A15,SPRECT_3:12;
              then G*(i,j)`2 <= G*(i,n)`2 by A46,A47,TOPREAL1:4;
              hence j <= n by A6,A19,A36,GOBOARD5:4;
              G*(i,n)`2 <= G*(i,k) `2 by A46,A47,A48,TOPREAL1:4;
              hence n <= k by A13,A11,A37,GOBOARD5:4;
              p`1 = G*(i,j)`1 by A20,A46,GOBOARD7:5
                .= G*(i,1)`1 by A6,A14,A19,GOBOARD5:2
                .= G*(i,n)`1 by A6,A36,A37,GOBOARD5:2;
              hence thesis by A47,TOPREAL3:6;
            end;
            suppose
A49:          not f/.i1 in LSeg(G*(i,j),G*(i,k));
A50:          (f/.i1)`1 = p`1 by A26,A40,GOBOARD7:5
                .= G*(i,j)`1 by A20,A9,GOBOARD7:5;
              thus thesis
              proof
                per cases by A20,A49,A50,GOBOARD7:7;
                suppose
A51:              (f/.i1)`2 < G*(i,j)`2;
                  p`2 <= G*(io,jo)`2 by A26,A29,A43,TOPREAL1:4;
                  then p`2 <= G*(1,jo)`2 by A30,A31,A38,GOBOARD5:1;
                  then p`2 <= G*(i,jo)`2 by A6,A31,A38,GOBOARD5:1;
                  then G*(i,j)`2 <= G*(i,jo)`2 by A17,XXREAL_0:2;
                  then
A52:              j<=jo by A6,A19,A31,GOBOARD5:4;
                  |.i0-io.|+|.j0-jo.| = 1 by A1,A32,A27,A33,A34,A28,A29,
GOBOARD1:def 9;
                  then 0+|.j0-jo.| = 1 by A42,A41,ABSVALUE:2;
                  then
A53:              |.-(j0-jo).| = 1 by COMPLEX1:52;
                  j0<=jo+0 by A34,A29,A35,A37,A31,A42,A41,A43,GOBOARD5:4;
                  then j0-jo <= 0 by XREAL_1:20;
                  then jo-j0 = 1 by A53,ABSVALUE:def 1;
                  then
A54:              j0+1=jo+0;
                  G*(i,j0)`2 < G*(i,j)`2 & j0<=j by A34,A6,A14,A37,A42,A51,
GOBOARD5:4 ;
                  then j0<j by XXREAL_0:1;
                  then jo<=j by A54,NAT_1:13;
                  then
A55:              j=jo by A52,XXREAL_0:1;
                  take n=jo;
A56:              p`1 = G*(i,j)`1 by A20,A9,GOBOARD7:5
                    .= G*(i,1)`1 by A6,A14,A19,GOBOARD5:2
                    .= G*(i,n)`1 by A6,A31,A38,GOBOARD5:2;
                  p`2 <= G*(io,jo)`2 by A26,A29,A43,TOPREAL1:4;
                  then p`2 <= G*(1,jo)`2 by A30,A31,A38,GOBOARD5:1;
                  then p`2 <= G*(i,jo)`2 by A6,A31,A38,GOBOARD5:1;
                  then p`2 = G*(i,j)`2 by A17,A55,XXREAL_0:1;
                  hence thesis by A5,A55,A56,TOPREAL3:6;
                end;
                suppose
A57:              (f/.i1)`2 > G*(i,k)`2;
                  p`2 >= (f/.i1)`2 by A26,A43,TOPREAL1:4;
                  hence thesis by A18,A57,XXREAL_0:2;
                end;
              end;
            end;
          end;
        end;
        suppose
A58:      (f/.i1)`2 > (f/.(i1+1))`2;
          thus thesis
          proof
            per cases;
            suppose
A59:          (f/.(i1+1)) in LSeg(G*(i,j),G*(i,k));
              1+1<=i1+1 by A24,XREAL_1:6;
              then f/.(i1+1) in L~f by A25,A27,GOBOARD1:1,XXREAL_0:2;
              then f/.(i1+1) in X1 by A59,XBOOLE_0:def 4;
              then
A60:          p`2 <= (f/.(i1+1))`2 by A10,A12,PSCOMP_1:24;
              take n=jo;
A61:          p in LSeg(G*(i,j),G*(i,k)) by A8,XBOOLE_0:def 4;
              p`2 >= (f/.(i1+1))`2 by A26,A58,TOPREAL1:4;
              then p`2 = (f/.(i1+1))`2 by A60,XXREAL_0:1;
              then
A62:          p`2 = G*(1,jo)`2 by A29,A30,A31,A38,GOBOARD5:1
                .= G*(i,n)`2 by A6,A31,A38,GOBOARD5:1;
A63:          G*(i,j)`2 <= G*(i,k)`2 by A5,A6,A14,A15,SPRECT_3:12;
              then G*(i,j)`2 <= G*(i,n)`2 by A61,A62,TOPREAL1:4;
              hence j <= n by A6,A19,A31,GOBOARD5:4;
              G*(i,n)`2 <= G*(i,k) `2 by A61,A62,A63,TOPREAL1:4;
              hence n <= k by A13,A11,A38,GOBOARD5:4;
              p`1 = G*(i,j)`1 by A20,A61,GOBOARD7:5
                .= G*(i,1)`1 by A6,A14,A19,GOBOARD5:2
                .= G*(i,n)`1 by A6,A31,A38,GOBOARD5:2;
              hence thesis by A62,TOPREAL3:6;
            end;
            suppose
A64:          not f/.(i1+1) in LSeg(G*(i,j),G*(i,k));
A65:          (f/.(i1+1))`1 = p`1 by A26,A40,GOBOARD7:5
                .= G*(i,j)`1 by A20,A9,GOBOARD7:5;
              thus thesis
              proof
                per cases by A20,A64,A65,GOBOARD7:7;
                suppose
A66:              (f/.(i1+1))`2 < G*(i,j)`2;
                  p`2 <= G*(i0,j0)`2 by A26,A34,A58,TOPREAL1:4;
                  then p`2 <= G*(1,j0)`2 by A35,A36,A37,GOBOARD5:1;
                  then p`2 <= G*(i,j0)`2 by A6,A36,A37,GOBOARD5:1;
                  then G*(i,j)`2 <= G*(i,j0)`2 by A17,XXREAL_0:2;
                  then
A67:              j<=j0 by A6,A19,A36,GOBOARD5:4;
                  jo<=j0+0 by A34,A29,A35,A36,A38,A42,A41,A58,GOBOARD5:4;
                  then jo-j0 <= 0 by XREAL_1:20;
                  then
A68:              -(jo-j0) >= -0;
                  |.i0-io.|+|.j0-jo.| = 1 by A1,A32,A27,A33,A34,A28,A29,
GOBOARD1:def 9;
                  then 0+|.j0-jo.| = 1 by A42,A41,ABSVALUE:2;
                  then j0-jo = 1 by A68,ABSVALUE:def 1;
                  then
A69:              jo+1=j0-0;
                  G*(i,jo)`2 < G*(i,j)`2 & jo<=j by A29,A6,A14,A38,A41,A66,
GOBOARD5:4 ;
                  then jo<j by XXREAL_0:1;
                  then j0<=j by A69,NAT_1:13;
                  then
A70:              j=j0 by A67,XXREAL_0:1;
                  take n=j0;
A71:              p`1 = G*(i,j)`1 by A20,A9,GOBOARD7:5
                    .= G*(i,1)`1 by A6,A14,A19,GOBOARD5:2
                    .= G*(i,n)`1 by A6,A36,A37,GOBOARD5:2;
                  p`2 <= G*(i0,j0)`2 by A26,A34,A58,TOPREAL1:4;
                  then p`2 <= G*(1,j0)`2 by A35,A36,A37,GOBOARD5:1;
                  then p`2 <= G*(i,j0)`2 by A6,A36,A37,GOBOARD5:1;
                  then p`2 = G*(i,j)`2 by A17,A70,XXREAL_0:1;
                  hence thesis by A5,A70,A71,TOPREAL3:6;
                end;
                suppose
A72:              (f/.(i1+1))`2 > G*(i,k)`2;
                  p`2 >= (f/.(i1+1))`2 by A26,A58,TOPREAL1:4;
                  hence thesis by A18,A72,XXREAL_0:2;
                end;
              end;
            end;
          end;
        end;
      end;
    end;
    suppose
A73:  (f/.i1)`2 = (f/.(i1+1))`2;
      take n=j0;
      p`2 = (f/.i1)`2 by A26,A73,GOBOARD7:6;
      then
A74:  p`2 = G*(1,j0)`2 by A34,A35,A36,A37,GOBOARD5:1
        .= G*(i,n)`2 by A6,A36,A37,GOBOARD5:1;
A75:  G*(i,j)`2 <= G*(i,k)`2 by A5,A6,A14,A15,SPRECT_3:12;
      then G*(i,j)`2 <= G*(i,n)`2 by A9,A74,TOPREAL1:4;
      hence j <= n by A6,A19,A36,GOBOARD5:4;
      G*(i,n)`2 <= G*(i,k)`2 by A9,A74,A75,TOPREAL1:4;
      hence n <= k by A13,A11,A37,GOBOARD5:4;
      p`1 = G*(i,j)`1 by A20,A9,GOBOARD7:5
        .= G*(i,1)`1 by A6,A14,A19,GOBOARD5:2
        .= G*(i,n)`1 by A6,A36,A37,GOBOARD5:2;
      hence thesis by A74,TOPREAL3:6;
    end;
  end;
  hence thesis by A12;
end;
