reserve m,k,j,j1,i,i1,i2,n for Nat,
  r,s for Real,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p for Point of TOP-REAL 2;

theorem Th1:
  for p,q being Point of TOP-REAL 2 st p <> q holds p in Cl(LSeg(p, q) \ {p,q})
proof
  let p,q be Point of TOP-REAL 2 such that
A1: p <> q;
  for G being Subset of TOP-REAL 2 st G is open holds p in G implies (LSeg
  (p,q) \ {p,q}) meets G
  proof
    reconsider x = p, y = q as Point of Euclid 2 by TOPREAL3:8;
    let G be Subset of TOP-REAL 2 such that
A2: G is open and
A3: p in G;
A4: the TopStruct of TOP-REAL 2 = TopSpaceMetr Euclid 2 by EUCLID:def 8;
    then reconsider P = G as Subset of TopSpaceMetr Euclid 2;
    P is open by A2,A4,PRE_TOPC:30;
    then consider r being Real such that
A5: r>0 and
A6: Ball(x,r) c= P by A3,TOPMETR:15;
    reconsider r as Real;
A7: r/2 > 0 by A5,XREAL_1:139;
    set t = min(r/2,dist(x,y)/2), s = t/dist(x,y);
    set pp = (1-s)*p+s*q;
    reconsider z = pp as Point of Euclid 2 by TOPREAL3:8;
    reconsider x9 = x, y9 = y, z9 = z as Element of REAL 2;
    reconsider a = x9, b = y9 as Element of 2-tuples_on REAL;
    reconsider u = a-b as Element of REAL 2;
A8: 0 < dist(x,y) by A1,METRIC_1:7;
    then 0 < dist(x,y)/2 by XREAL_1:139;
    then
A9: 0 < t by A7,XXREAL_0:21;
    dist(x,z) = |.x9-z9.| by SPPOL_1:5
      .= |.a-(1-s)*a-s*b.| by RVSUM_1:39
      .= |.1 *a-(1-s)*a-s*b.| by RVSUM_1:52
      .= |.1 *a +(-1)*(1-s)*a-s*b.| by RVSUM_1:49
      .= |.(1+ (-(1-s)))*a-s*b.| by RVSUM_1:50
      .= |.s*a+ (-1)*s*b.| by RVSUM_1:49
      .= |.s*a+ s*((-1)*b).| by RVSUM_1:49
      .= |.s*(a+ (-1)*b).| by RVSUM_1:51
      .= |.s*(a+ -b).|
      .= |.s*(a-b).|
      .= |.s.|*|.u.| by EUCLID:11
      .= s*|.a-b.| by A8,A9,ABSVALUE:def 1
      .= s*dist(x,y) by SPPOL_1:5
      .= t by A8,XCMPLX_1:87;
    then
A10: dist(x,z) <= r/2 by XXREAL_0:17;
    r/2 < r/1 by A5,XREAL_1:76;
    then dist(x,z) < r by A10,XXREAL_0:2;
    then
A11: z in Ball(x,r) by METRIC_1:11;
A12: (1-s)*p+s*p = (1-s+s)*p by RLVECT_1:def 6
      .= p by RLVECT_1:def 8;
    t <= dist(x,y)/2 & dist(x,y)/2 < dist(x,y)/1 by A8,XREAL_1:76,XXREAL_0:17;
    then
A13: t < dist(x,y) by XXREAL_0:2;
    then s < 1 by A9,XREAL_1:189;
    then
A14: pp in LSeg(p,q) by A8,A9;
A15: (1-s)*q+s*q = (1-s+s)*q by RLVECT_1:def 6
      .= q by RLVECT_1:def 8;
A16: 1-s <> 0 by A9,A13,XREAL_1:189;
A17: now
      assume pp = q;
      then (1-s)*q = pp - s*q by A15,RLVECT_4:1
        .= (1-s)*p by RLVECT_4:1;
      hence contradiction by A1,A16,RLVECT_1:36;
    end;
A18: 0 < s by A8,A9,XREAL_1:139;
    now
      assume pp = p;
      then s*p = pp - (1-s)*p by A12,RLVECT_4:1
        .= s*q by RLVECT_4:1;
      hence contradiction by A1,A18,RLVECT_1:36;
    end;
    then not pp in {p,q} by A17,TARSKI:def 2;
    then pp in LSeg(p,q) \ {p,q} by A14,XBOOLE_0:def 5;
    hence thesis by A6,A11,XBOOLE_0:3;
  end;
  hence thesis by TOPS_1:12;
end;
