reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem
  for n being Nat
  ex f being Function of TOP-REAL n,R^1 st for p being Element of
  TOP-REAL n holds f.p=p/.i
proof
  let n be Nat;
  defpred P[object,object] means
   for p being Element of TOP-REAL n st $1=p holds $2= p/.i;
A1: for x being object st x in REAL n ex y being object st y in REAL & P[x,y]
  proof
    let x be object;
    assume x in REAL n;
    then reconsider px=x as Element of TOP-REAL n by EUCLID:22;
    consider q being Real,g being FinSequence of REAL such that
A2: g=px and
    q=g/.i by Lm1;
    for p being Element of TOP-REAL n st x=p holds g/.i=p/.i by A2;
    hence thesis;
  end;
  ex f being Function of REAL n,REAL st
for x being object st x in REAL n holds P[x,f.x] from FUNCT_2:sch 1(A1);
  then consider f being Function of REAL n,REAL such that
A3: for x being object st x in REAL n
for p being Element of TOP-REAL n st x=p
  holds f.x=p/.i;
  the carrier of TOP-REAL n=REAL n by EUCLID:22;
  then reconsider f1=f as Function of TOP-REAL n,R^1 by TOPMETR:17;
  for p being Element of TOP-REAL n holds f1.p=p/.i
  proof
    let p be Element of TOP-REAL n;
    p in the carrier of TOP-REAL n;
    then p in REAL n by EUCLID:22;
    hence thesis by A3;
  end;
  hence thesis;
end;
