reserve X,Y,Z for non trivial RealBanachSpace;

theorem LOPBAN410:
  for X be RealNormSpace, seq be sequence of X, k be Nat
  holds ||.Partial_Sums(seq).k.|| <= Partial_Sums(||.seq.||).k
  proof
    let X be RealNormSpace, seq be sequence of X;
    defpred P[Nat] means
    ||. Partial_Sums(seq).$1 .|| <= Partial_Sums(||.seq.||).$1;
    A1: now
      let k be Nat;
      assume P[k]; then
      A2: ||.Partial_Sums(seq).k.|| + ||.(seq).(k+1).||
       <= Partial_Sums(||.seq.|| ).k + ||.(seq).(k+1).|| by XREAL_1:6;
      A3: ||. Partial_Sums(seq).k + (seq).(k+1) .||
       <= ||. Partial_Sums(seq).k .|| + ||. (seq).(k+1) .|| by NORMSP_1:def 1;
      ||. Partial_Sums(seq).(k+1) .||
      = ||. Partial_Sums(seq).k + (seq).(k+1) .|| by BHSP_4:def 1; then
      ||. Partial_Sums(seq).(k+1) .||
       <= Partial_Sums(||.seq.||).k + ||.seq.(k+1).|| by A3,A2,XXREAL_0:2; then
      ||. Partial_Sums(seq).(k+1) .||
       <= Partial_Sums(||.seq.||).k+||.seq.||.(k+1) by NORMSP_0:def 4;
      hence P[k+1] by SERIES_1:def 1;
    end;
    Partial_Sums(||.seq.||).0 = (||.seq.||).0 by SERIES_1:def 1
    .= ||. seq.0 .|| by NORMSP_0:def 4; then
    A4: P[0] by BHSP_4:def 1;
    for k be Nat holds P[k] from NAT_1:sch 2(A4,A1);
    hence thesis;
  end;
