reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);

theorem Th1:
  width A = len B implies (a*A) * B = a * (A*B)
proof
  set aA=a*A;
  set AB=A*B;
  set aAB=a*AB;
  assume
A1: width A=len B;
  then
A2: width AB=width B by MATRIX_3:def 4;
A3: len aAB=len AB by MATRIX_3:def 5;
  then
A4: len aAB = len A by A1,MATRIX_3:def 4;
A5: width aA=width A by MATRIX_3:def 5;
  then
A6: len aA=len A & len aA=len (aA*B) by A1,MATRIX_3:def 4,def 5;
A7: now
    let i,j;
    assume [i,j] in Indices aAB;
    then
A8: [i,j] in Indices AB by MATRIXR1:18;
    then i in dom AB by ZFMISC_1:87;
    then i in Seg len A by A3,A4,FINSEQ_1:def 3;
    then
A9: 1<=i & i<=len A by FINSEQ_1:1;
    dom AB = Seg len AB by FINSEQ_1:def 3
      .= dom (aA*B) by A3,A4,A6,FINSEQ_1:def 3;
    then
A10: [i,j] in Indices (aA*B) by A1,A5,A2,A8,MATRIX_3:def 4;
    thus aAB*(i,j) = a*(AB*(i,j)) by A8,MATRIX_3:def 5
      .= a*(Line(A,i)"*"Col(B,j)) by A1,A8,MATRIX_3:def 4
      .= Sum(a*mlt(Line(A,i),Col(B,j))) by FVSUM_1:73
      .= Sum(mlt(a*Line(A,i),Col(B,j))) by A1,FVSUM_1:68
      .= Line(aA,i)"*"Col(B,j) by A9,MATRIXR1:20
      .= (aA*B)*(i,j) by A1,A5,A10,MATRIX_3:def 4;
  end;
  width aAB=width AB & width B=width (aA*B) by A1,A5,MATRIX_3:def 4,def 5;
  hence thesis by A2,A4,A6,A7,MATRIX_0:21;
end;
