reserve i, k, m, n for Nat,
  r, s for Real,
  rn for Real,
  x, y , z, X for set,
  T, T1, T2 for non empty TopSpace,
  p, q for Point of T,
  A, B, C for Subset of T,
  A9 for non empty Subset of T,
  pq for Element of [:the carrier of T,the carrier of T:],
  pq9 for Point of [:T,T:],
  pmet,pmet1 for Function of [:the carrier of T,the carrier of T:],REAL,
  pmet9,pmet19 for RealMap of [:T,T:] ,
  f,f1 for RealMap of T,
  FS2 for Functional_Sequence of [:the carrier of T,the carrier of T:],REAL,
  seq for Real_Sequence;

theorem Th1:
  for i st i>0 ex n,m st i=(2|^n)*(2*m+1)
proof
  defpred N[Nat] means
  for k st 1<=k & k<=$1 ex n,m st k=(2|^n)*(2*m+1);
A1: for i st N[i] holds N[i + 1]
  proof
    let i such that
A2: N[i];
    let k such that
A3: 1<=k and
A4: k <=i+1;
    now
      per cases by A4,XXREAL_0:1;
      suppose
A5:     k=i+1 & i=0;
        set m=0;
A6:     1=2|^0 by NEWTON:4;
        k=1*(m*2+1) by A5;
        hence thesis by A6;
      end;
      suppose
A7:     k=i+1 & i>0;
        per cases by NAT_D:12;
        suppose
          k mod 2=1;
          then consider m being Nat such that
A8:       k = 2 * m + 1 and
          1<2 by NAT_D:def 2;
          reconsider m as Element of NAT by ORDINAL1:def 12;
          1=2|^0 by NEWTON:4;
          then k=(2|^0)*(2*m+1) by A8;
          hence thesis;
        end;
        suppose
          k mod 2=0;
          then consider j being Nat such that
A9:       k = 2 * j + 0 and
          0<2 by NAT_D:def 2;
          reconsider j as Element of NAT by ORDINAL1:def 12;
A10:      j<=i
          proof
            assume j>i;
            then j+j>i+1 by NAT_1:14,XREAL_1:8;
            hence thesis by A7,A9;
          end;
          j<>0 by A7,A9;
          then j>=1 by NAT_1:14;
          then consider n,m such that
A11:      j=(2|^n)*(2*m+1) by A2,A10;
          k=(2*(2|^n))*(2*m+1) by A9,A11;
          then k=(2|^(n+1))*(2*m+1) by NEWTON:6;
          hence thesis;
        end;
      end;
      suppose
        k<i+1;
        then k<=i by NAT_1:13;
        hence thesis by A2,A3;
      end;
    end;
    hence thesis;
  end;
  let i;
  assume i>0;
  then
A12: i>=1 by NAT_1:14;
A13: N[ 0 ];
  for n holds N[n] from NAT_1:sch 2(A13,A1);
  hence thesis by A12;
end;
