reserve F for RealNormSpace;
reserve G for RealNormSpace;
reserve X for set;
reserve x,x0,g,r,s,p for Real;
reserve n,m,k for Element of NAT;
reserve Y for Subset of REAL;
reserve Z for open Subset of REAL;
reserve s1,s3 for Real_Sequence;
reserve seq for sequence of G;
reserve f,f1,f2 for PartFunc of REAL,the carrier of F;
reserve h for 0-convergent non-zero Real_Sequence;
reserve c for constant Real_Sequence;

theorem Th1:
  (for n holds ||. seq.n .|| <= s1.n) & s1 is convergent & lim s1=0 implies
    seq is convergent & lim(seq)=0.G
  proof
    assume that
    A1: for n holds ||. seq.n .|| <= s1.n and
    A2: s1 is convergent and
    A3: lim(s1)=0;
    now
      let p be Real;
      assume 0<p;
      then consider n being Nat such that
      A4: for m being Nat st n<=m holds |.s1.m-0 .|<p by A2,A3,SEQ_2:def 7;
      reconsider n as Element of NAT by ORDINAL1:def 12;
      now
        let m be Nat;
A5:      m in NAT by ORDINAL1:def 12;
        assume n<=m; then
        A6: |.s1.m-0 .|<p by A4;
        A7: ||. seq.m-0.G .|| = ||. seq.m .|| by RLVECT_1:13;
        A8: s1.m <= |.s1.m.| by ABSVALUE:4;
        ||. seq.m .|| <= s1.m by A1,A5;
        then ||. seq.m - 0.G .|| <= |.s1.m.| by A7,A8,XXREAL_0:2;
        hence ||. seq.m - 0.G .|| < p by A6,XXREAL_0:2;
      end;
      hence ex n being Nat st
          for m being Nat st n<=m holds ||. seq.m - (0.G) .|| < p;
    end; then
A9: for p be Real st 0<p
    ex n being Nat st for m being Nat st n<=m
    holds ||. seq.m - 0.G .|| < p;
    hence seq is convergent by NORMSP_1:def 6;
    hence thesis by A9,NORMSP_1:def 7;
  end;
