reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;

theorem Th1:
  for B being non empty set, f being Function holds
  f " (union B)
  = union the set of all f "Y where Y is Element of B
  proof
    let B be non empty set, f be Function;
    set Z = the set of all f "Y where Y is Element of B ;
    thus f " (union B) c= union Z
    proof
      let x be object;
      assume A1: x in f " (union B);
      then f . x in union B by FUNCT_1:def 7;
      then consider Y being set such that
      A2: f . x in Y and
      A3: Y in B by TARSKI:def 4;
      reconsider Y as Element of B by A3;
      x in dom f by A1, FUNCT_1:def 7; then
      A4: x in f " Y by A2,FUNCT_1:def 7;
      f " Y in Z;
      hence x in union Z by A4,TARSKI:def 4;
    end;
    let x be object;
    assume x in union Z;
    then consider Y being set such that
A5: x in Y and
A6: Y in Z by TARSKI:def 4;
    consider D be Element of B such that
A7: Y = f " D by A6;
    f " D c= f "(union B) by RELAT_1:143,ZFMISC_1:74;
    hence x in f "(union B) by A5,A7;
  end;
