reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th1:
  for L be Linear_Combination of A st L is convex & v <> Sum L & L.v <> 0
   ex p st p in conv(A\{v}) & Sum L = L.v*v + (1-L.v)*p &
           1/L.v*(Sum L) + (1-1/L.v)*p = v
  proof
    let L be Linear_Combination of A such that
    A1: L is convex and
    A2: v<>Sum L and
    A3: L.v<>0;
    set Lv=L.v,1Lv=1-L.v;
    A4: Carrier L c=A by RLVECT_2:def 6;
    Carrier L<>{} by A1,CONVEX1:21;
    then reconsider A1=A as non empty Subset of V by A4;
    consider K be Linear_Combination of{v} such that
    A5: K.v=Lv by RLVECT_4:37;
    A6: Lv<>1
    proof
      assume A7: Lv=1;
      then Carrier L={v} by A1,RLAFFIN1:64;
      then Sum L=1*v by A7,RLVECT_2:35
               .=v by RLVECT_1:def 8;
      hence contradiction by A2;
    end;
    Lv<=1 by A1,RLAFFIN1:63;
    then Lv<1 by A6,XXREAL_0:1;
    then A8: 1Lv>1-1 by XREAL_1:10;
    v in Carrier L by A3;
   then {v}c=A1 by A4,ZFMISC_1:31;
    then K is Linear_Combination of A1 by RLVECT_2:21;
    then reconsider LK=L-K as Linear_Combination of A1 by RLVECT_2:56;
    1/1Lv*LK is Linear_Combination of A by RLVECT_2:44;
    then A9: Carrier(1/1Lv*LK)c=A1 by RLVECT_2:def 6;
    LK.v=Lv-Lv by A5,RLVECT_2:54;
    then A10: (1/1Lv*LK).v=1/1Lv*(Lv-Lv) by RLVECT_2:def 11;
    then not v in Carrier(1/1Lv*LK) by RLVECT_2:19;
    then A11: Carrier(1/1Lv*LK)c=A\{v} by A9,ZFMISC_1:34;
    A12: Carrier K c={v} by RLVECT_2:def 6;
    A13: for w be Element of V holds(1/1Lv*LK).w>=0
    proof
      let w be Element of V;
      A14: (1/1Lv*LK).w=(1/1Lv)*(LK.w) by RLVECT_2:def 11
      .=(1/1Lv)*(L.w-K.w) by RLVECT_2:54;
      per cases;
      suppose w=v;
        hence thesis by A10;
      end;
      suppose w<>v;
        then not w in Carrier K by A12,TARSKI:def 1;
        then A15: K.w=0;
        L.w>=0 by A1,RLAFFIN1:62;
        hence thesis by A8,A14,A15;
      end;
    end;
    sum LK=sum L-sum K by RLAFFIN1:36
    .=sum L-Lv by A5,A12,RLAFFIN1:32
    .=1Lv by A1,RLAFFIN1:62;
    then A16: sum(1/1Lv*LK)=1/1Lv*1Lv by RLAFFIN1:35
    .=1 by A8,XCMPLX_1:106;
    then 1/1Lv*LK is convex by A13,RLAFFIN1:62;
    then Carrier(1/1Lv*LK)<>{} by CONVEX1:21;
    then reconsider Av=A\{v} as non empty Subset of V by A11;
    reconsider 1LK=1/1Lv*LK as Convex_Combination of Av
      by A11,A13,A16,RLAFFIN1:62,RLVECT_2:def 6;
    take p=Sum 1LK;
    1LK in ConvexComb(V) by CONVEX3:def 1;
    then p in {Sum(M) where M is Convex_Combination of Av:M in ConvexComb(V)};
    hence p in conv(A\{v}) by CONVEX3:5;
    A17: Sum(LK)=Sum L-Sum K by RLVECT_3:4
               .=Sum L-Lv*v by A5,RLVECT_2:32;
    then 1Lv*p=1Lv*(1/1Lv*(Sum L-Lv*v)) by RLVECT_3:2
             .=(1Lv*(1/1Lv))*(Sum L-Lv*v) by RLVECT_1:def 7
             .=1*(Sum L-Lv*v) by A8,XCMPLX_1:106
             .=Sum L-Lv*v by RLVECT_1:def 8;
    hence Sum L=Lv*v+1Lv*p by RLVECT_4:1;
    1-1/Lv=Lv/Lv-1/Lv by A3,XCMPLX_1:60
         .=(Lv-1)/Lv by XCMPLX_1:120
         .=(-1Lv)/Lv
         .=-1Lv/Lv by XCMPLX_1:187;
    then (1-1/Lv)*Sum 1LK=(-1Lv/Lv)*(1/1Lv*(Sum L-Lv*v)) by A17,RLVECT_3:2
                        .=((-1Lv/Lv)*(1/1Lv))*(Sum L-Lv*v) by RLVECT_1:def 7
                        .=(-(1Lv/Lv)*(1/1Lv))*(Sum L-Lv*v)
                        .=(-(1Lv/1Lv)*(1/Lv))*(Sum L-Lv*v) by XCMPLX_1:85
                        .=(-1*(1/Lv))*(Sum L-Lv*v) by A8,XCMPLX_1:60
                        .=(-(1/Lv))*(Sum L)-(-(1/Lv))*(Lv*v) by RLVECT_1:34
                        .=(-(1/Lv))*(Sum L)+-(-(1/Lv))*(Lv*v)
                           by RLVECT_1:def 11
                        .=(-(1/Lv))*(Sum L)+(-(-(1/Lv)))*(Lv*v) by RLVECT_4:3
                        .=(-(1/Lv))*(Sum L)+(1/Lv*Lv)*v by RLVECT_1:def 7
                        .=(-(1/Lv))*(Sum L)+1*v by A3,XCMPLX_1:106
                        .=(-(1/Lv))*(Sum L)+v by RLVECT_1:def 8
                        .=-((1/Lv)*(Sum L))+v by RLVECT_4:3;
    hence 1/Lv*(Sum L)+(1-1/Lv)*p =(1/Lv*Sum L+-(1/Lv)*(Sum L))+v
                     by RLVECT_1:def 3
                 .=(1/Lv*Sum L-(1/Lv)*(Sum L))+v by RLVECT_1:def 11
                 .=v by RLVECT_4:1;
  end;
