reserve i,j,l for Nat;

theorem Th1:
  for f being S-Sequence_in_R2, Q being closed Subset of TOP-REAL 2
st L~f meets Q & not f/.1 in Q holds L~R_Cut(f,First_Point(L~f,f/.1,f/.len f,Q)
  ) /\ Q = { First_Point(L~f,f/.1,f/.len f,Q) }
proof
  let f be S-Sequence_in_R2, Q be closed Subset of TOP-REAL 2 such that
A1: L~f meets Q and
A2: not f/.1 in Q;
  set p1 = f/.1, p2 = f/.len f, fp = First_Point(L~f,p1,p2,Q);
A3: L~f /\ Q is closed by TOPS_1:8;
  len f >= 1+1 by TOPREAL1:def 8;
  then
A4: len f > 1 by NAT_1:13; then
AA: 1 in dom f by FINSEQ_3:25;
  L~f is_an_arc_of p1,p2 by TOPREAL1:25;
  then
A5: fp in L~f /\ Q by A1,A3,JORDAN5C:def 1;
  then
A6: fp in L~f by XBOOLE_0:def 4;
  then
A7: 1<=Index(fp,f) by JORDAN3:8;
A8: Index(fp,f)<=len f by A6,JORDAN3:8;
  then
A9: Index(fp,f) in dom f by A7,FINSEQ_3:25;
A10: now
    assume not L~R_Cut(f,fp) /\ Q c= { fp };
    then consider q being object such that
A11: q in L~R_Cut(f,fp) /\ Q and
A12: not q in { fp } by TARSKI:def 3;
    reconsider q as Point of TOP-REAL 2 by A11;
A13: q in L~R_Cut(f,fp) by A11,XBOOLE_0:def 4;
A14: L~R_Cut(f,fp) c= L~f by A6,JORDAN3:41;
A15: q <> fp by A12,TARSKI:def 1;
    q in Q by A11,XBOOLE_0:def 4;
    then
A16: LE fp, q, L~f, p1, p2 by A3,A13,A14,JORDAN5C:15;
    per cases;
    suppose
A17:  fp = f.1;
A18:  len<*fp*> = 1 by FINSEQ_1:39;
      q in L~<*fp*> by A13,A17,JORDAN3:def 4;
      hence contradiction by A18,TOPREAL1:22;
    end;
    suppose
A19:  fp <> f.1;
      set m = mid(f,1,Index(fp,f));
A20:  Index(fp,f) < len f by A6,JORDAN3:8;
      len m = Index(fp,f)-'1+1 by A7,A8,FINSEQ_6:186;
      then
A21:  m is non empty by CARD_1:27;
A22:  fp in LSeg(f,Index(fp,f)) by A6,JORDAN3:9;
      q in L~(m^<*fp*>) by A13,A19,JORDAN3:def 4;
      then
A23:  q in L~m \/ LSeg(m/.len m,fp) by A21,SPPOL_2:19;
      now
        per cases by A23,XBOOLE_0:def 3;
        suppose
A24:      q in L~m;
A25:      now
            assume Index(fp,f) <= 1;
            then Index(fp,f) = 1 by A7,XXREAL_0:1;
            then len m = 1 by AA,FINSEQ_6:193;
            hence contradiction by A24,TOPREAL1:22;
          end;
          then
A26:      LE q, f/.Index(fp,f), L~f, p1, p2 by A8,A24,SPRECT_3:17;
          f/.Index(fp,f) in LSeg(f/.Index(fp,f),fp) by RLTOPSP1:68;
          then LE f/.Index(fp,f), fp, L~f, p1, p2 by A20,A22,A25,SPRECT_3:23;
          then LE q, fp, L~f, p1, p2 by A26,JORDAN5C:13;
          hence contradiction by A15,A16,JORDAN5C:12,TOPREAL1:25;
        end;
        suppose
A27:      q in LSeg(m/.len m,fp);
          len m in dom m by A21,FINSEQ_5:6;
          then m/.len m = m.len m by PARTFUN1:def 6
            .= f.Index(fp,f) by A7,A8,FINSEQ_6:188
            .= f/.Index(fp,f) by A9,PARTFUN1:def 6;
          then LE q, fp, L~f, p1, p2 by A7,A20,A22,A27,SPRECT_3:23;
          hence contradiction by A15,A16,JORDAN5C:12,TOPREAL1:25;
        end;
      end;
      hence contradiction;
    end;
  end;
A28: fp in Q by A5,XBOOLE_0:def 4;
  1 in dom f by A4,FINSEQ_3:25;
  then fp <> f.1 by A2,A28,PARTFUN1:def 6;
  then fp in L~R_Cut(f,fp) by A6,JORDAN5B:20;
  then fp in L~R_Cut(f,fp) /\ Q by A28,XBOOLE_0:def 4;
  hence thesis by A10,ZFMISC_1:33;
end;
