reserve K,F for Ring;
reserve V,W for VectSp of K;
reserve l for Linear_Combination of V;
reserve T for linear-transformation of V,W;

theorem
  for K being Field,
  V,W being finite-dimensional VectSp of K,
  A being Subset of V,
  B being Basis of V,
  T being linear-transformation of V, W,
  l being Linear_Combination of B \ A
  st A is Basis of ker T & A c= B holds T.(Sum l) = Sum(T@*l)
  proof
    let K be Field,
    V,W be finite-dimensional VectSp of K,
    A be Subset of V, B be Basis of V,
    T be linear-transformation of V,W,
    l be Linear_Combination of B \ A;
    assume A is Basis of ker T & A c= B; then
    A1: T | (B \ A) is one-to-one by RANKNULL:22;
    A2: (T | (B \ A)) | (Carrier l) = T | (Carrier l)
    by RELAT_1:74,VECTSP_6:def 4; then
    A3: T | (Carrier l) is one-to-one by A1,FUNCT_1:52;
    consider G be FinSequence of V such that
    A4: G is one-to-one and
    A5: rng G = Carrier l and
    A6: Sum l = Sum (l (#) G) by VECTSP_6:def 6;
    set H = T*G;
    A7: rng H = T .: (Carrier l) by A5,RELAT_1:127
    .= Carrier(T@*l) by A3,ZMODUL05:56;
    dom T = [#]V by RANKNULL:7;
    then H is one-to-one by A1,A2,A4,A5,FUNCT_1:52,RANKNULL:1; then
    A8: Sum (T@*l) = Sum ((T@*l) (#) H) by A7,VECTSP_6:def 6;
    T*(l (#) G) = (T@*l) (#) H by A3,A5,ZMODUL05:55;
    hence thesis by A6,A8,MATRLIN:16;
  end;
