
theorem Th1:
  for S,T, S9,T9 being non empty RelStr
  st the RelStr of S = the RelStr of S9 & the RelStr of T = the RelStr of T9
  for c being Connection of S,T, c9 being Connection of S9,T9 st c = c9
  holds c is Galois implies c9 is Galois
proof
  let S,T, S9,T9 being non empty RelStr such that
A1: the RelStr of S = the RelStr of S9 and
A2: the RelStr of T = the RelStr of T9;
  let c be Connection of S,T, c9 be Connection of S9,T9 such that
A3: c = c9;
  given g being Function of S,T, d being Function of T,S such that
A4: c = [g,d] and
A5: g is monotone and
A6: d is monotone and
A7: for t being Element of T, s being Element of S holds t <= g.s iff d.t <= s;
  reconsider g9 = g as Function of S9, T9 by A1,A2;
  reconsider d9 = d as Function of T9, S9 by A1,A2;
  take g9,d9;
  thus c9 = [g9,d9] by A3,A4;
  thus g9 is monotone & d9 is monotone by A1,A2,A5,A6,WAYBEL_9:1;
  let t9 be Element of T9, s9 be Element of S9;
  reconsider t = t9 as Element of T by A2;
  reconsider s = s9 as Element of S by A1;
A8: t9 <= g9.s9 iff t <= g.s by A2,YELLOW_0:1;
  d9.t9 <= s9 iff d.t <= s by A1,YELLOW_0:1;
  hence thesis by A7,A8;
end;
