reserve H for ZF-formula,
  M,E for non empty set,
  e for Element of E,
  m,m0,m3, m4 for Element of M,
  v,v1,v2 for Function of VAR,M,
  f,f1 for Function of VAR,E,
  g for Function,
  u,u1,u2 for set,
  x,y for Variable,
  i,n for Element of NAT,
  X for set;

theorem Th1:
  E is epsilon-transitive implies Section(All(x.2,x.2 'in' x.0 =>
  x.2 'in' x.1),f/(x.1,e)) = E /\ bool e
proof
  set H = All(x.2,x.2 'in' x.0 => x.2 'in' x.1), v = f/(x.1,e);
  set S = Section(H,v);
  Free H=Free(x.2 'in' x.0 => x.2 'in' x.1)\{x.2} by ZF_LANG1:62
    .=(Free(x.2 'in' x.0) \/ Free(x.2 'in' x.1))\{x.2} by ZF_LANG1:64
    .=(Free(x.2 'in' x.0) \/ {x.2,x.1})\{x.2} by ZF_LANG1:59
    .=({x.2,x.0} \/ {x.2,x.1})\{x.2} by ZF_LANG1:59
    .=({x.2,x.0}\{x.2}) \/ ({x.2,x.1}\{x.2}) by XBOOLE_1:42
    .=({x.2,x.0}\{x.2}) \/ {x.1} by ZFMISC_1:17,ZF_LANG1:76
    .={x.0} \/ {x.1} by ZFMISC_1:17,ZF_LANG1:76
    .={x.0,x.1} by ENUMSET1:1;
  then x.0 in Free H by TARSKI:def 2;
  then
A1: S={m where m is Element of E: E,v/(x.0,m)|= H} by Def1;
  assume
A2: X in E implies X c= E;
  thus S c= E /\ bool e
  proof
    let u be object;
    assume u in S;
    then consider m being Element of E such that
A3: u = m and
A4: E,v/(x.0,m) |= H by A1;
A5: m c= E by A2;
    m c= e
    proof
      let u1 be object;
      assume
A6:   u1 in m;
      then reconsider u1 as Element of E by A5;
A7:   v/(x.0,m)/(x.2,u1).(x.2) = u1 by FUNCT_7:128;
A8:   E,v/(x.0,m)/(x.2,u1) |= x.2 'in' x.0 => x.2 'in' x.1 by A4,ZF_LANG1:71;
A9:   v/(x.0,m)/(x.2,u1).(x.1) = v/(x.0,m).(x.1) & v.(x.1) = v/(x.0,m).(
      x.1) by FUNCT_7:32,ZF_LANG1:76;
      m = v/(x.0,m).(x.0) & v/(x.0,m)/(x.2,u1).(x.0) = v/(x.0,m).(x.0) by
FUNCT_7:32,128,ZF_LANG1:76;
      then E,v/(x.0,m)/(x.2,u1) |= x.2 'in' x.0 by A6,A7,ZF_MODEL:13;
      then v.x.1 = e & E,v/(x.0,m)/(x.2,u1) |= x.2 'in' x.1 by A8,FUNCT_7:128
,ZF_MODEL:18;
      hence thesis by A7,A9,ZF_MODEL:13;
    end;
    then u in bool e by A3,ZFMISC_1:def 1;
    hence thesis by A3,XBOOLE_0:def 4;
  end;
  let u be object;
  assume
A10: u in E /\ bool e;
  then
A11: u in bool e by XBOOLE_0:def 4;
  reconsider u as Element of E by A10,XBOOLE_0:def 4;
  now
A12: v.x.1 = e by FUNCT_7:128;
    let m be Element of E;
A13: v/(x.0,u)/(x.2,m).(x.2) = m by FUNCT_7:128;
A14: u = v/(x.0,u).(x.0) & v/(x.0,u)/(x.2,m).(x.0) = v/(x.0,u).(x.0) by
FUNCT_7:32,128,ZF_LANG1:76;
A15: v/(x.0,u)/(x.2,m).(x.1) = v/(x.0,u).(x.1) & v.(x.1) = v/(x.0,u).(x.1)
    by FUNCT_7:32,ZF_LANG1:76;
    now
      assume E,v/(x.0,u)/(x.2,m) |= x.2 'in' x.0;
      then m in u by A13,A14,ZF_MODEL:13;
      hence E,v/(x.0,u)/(x.2,m) |= x.2 'in' x.1 by A11,A13,A15,A12,ZF_MODEL:13;
    end;
    hence E,v/(x.0,u)/(x.2,m) |= x.2 'in' x.0 => x.2 'in' x.1 by ZF_MODEL:18;
  end;
  then E,v/(x.0,u) |= H by ZF_LANG1:71;
  hence thesis by A1;
end;
