reserve x,y,z,x1,x2,x3,x4,y1,y2,s for Variable,
  M for non empty set,
  a,b for set,
  i,j,k for Element of NAT,
  m,m1,m2,m3,m4 for Element of M,
  H,H1,H2 for ZF-formula,
  v,v9,v1,v2 for Function of VAR,M;

theorem Th1:
  Free (H/(x,y)) c= (Free H \ {x}) \/ {y}
proof
  defpred P[ZF-formula] means Free ($1/(x,y)) c= (Free $1 \ {x}) \/ {y};
A1: for x1,x2 holds P[x1 '=' x2] & P[x1 'in' x2]
  proof
    let x1,x2;
A2: x2 = x or x2 <> x;
    x1 = x or x1 <> x;
    then consider y1,y2 such that
A3: x1 <> x & x2 <> x & y1 = x1 & y2 = x2 or x1 = x & x2 <> x & y1 = y
& y2 = x2 or x1 <> x & x2 = x & y1 = x1 & y2 = y or x1 = x & x2 = x & y1 = y &
    y2 = y by A2;
A4: {y1,y2} c= ({x1,x2} \ {x}) \/ {y}
    proof
      let a be object;
      assume a in {y1,y2};
      then (a = x1 or a = x2) & a <> x or a = y by A3,TARSKI:def 2;
      then a in {x1,x2} & not a in {x} or a in {y} by TARSKI:def 1,def 2;
      then a in {x1,x2} \ {x} or a in {y} by XBOOLE_0:def 5;
      hence thesis by XBOOLE_0:def 3;
    end;
    (x1 'in' x2)/(x,y) = y1 'in' y2 by A3,ZF_LANG1:154;
    then
A5: Free ((x1 'in' x2)/(x,y)) = {y1,y2} by ZF_LANG1:59;
    (x1 '=' x2)/(x,y) = y1 '=' y2 by A3,ZF_LANG1:152;
    then Free ((x1 '=' x2)/(x,y)) = {y1,y2} by ZF_LANG1:58;
    hence thesis by A5,A4,ZF_LANG1:58,59;
  end;
A6: for H1,H2 st P[H1] & P[H2] holds P[H1 '&' H2]
  proof
    let H1,H2;
    assume that
A7: P[H1] and
A8: P[H2];
A9: Free ((H1/(x,y)) '&' (H2/(x,y))) = Free (H1/(x,y)) \/ Free (H2/(x, y
    )) by ZF_LANG1:61;
A10: ((Free H1 \ {x}) \/ {y}) \/ ((Free H2 \ {x}) \/ {y}) c= ((Free H1 \/
    Free H2) \ {x}) \/ {y}
    proof
      let a be object;
      assume a in ((Free H1 \ {x}) \/ {y}) \/ ((Free H2 \ {x}) \/ {y});
      then a in (Free H1 \ {x}) \/ {y} or a in (Free H2 \ {x}) \/ {y} by
XBOOLE_0:def 3;
      then a in Free H1 \ {x} or a in Free H2 \ {x} or a in {y} by
XBOOLE_0:def 3;
      then (a in Free H1 or a in Free H2) & not a in {x} or a in {y} by
XBOOLE_0:def 5;
      then a in Free H1 \/ Free H2 & not a in {x} or a in {y} by XBOOLE_0:def 3
;
      then a in (Free H1 \/ Free H2) \ {x} or a in {y} by XBOOLE_0:def 5;
      hence thesis by XBOOLE_0:def 3;
    end;
A11: (H1 '&' H2)/(x,y) = (H1/(x,y)) '&' (H2/(x,y)) by ZF_LANG1:158;
A12: Free (H1 '&' H2) = Free H1 \/ Free H2 by ZF_LANG1:61;
    Free (H1/(x,y)) \/ Free (H2/(x,y)) c= ((Free H1 \ {x}) \/ {y}) \/ ((
    Free H2 \ {x}) \/ {y}) by A7,A8,XBOOLE_1:13;
    hence thesis by A9,A12,A11,A10,XBOOLE_1:1;
  end;
A13: for H,z st P[H] holds P[All(z,H)]
  proof
    let H,z;
A14: Free All(z,H) = Free H \ {z} by ZF_LANG1:62;
    z = x or z <> x;
    then consider s such that
A15: z = x & s = y or z <> x & s = z;
A16: ((Free H \ {x}) \/ {y}) \ {s} c= ((Free H \ {z}) \ {x}) \/ {y}
    proof
      let a be object;
      assume
A17:  a in ((Free H \ {x}) \/ {y}) \ {s};
      then a in Free H \ {x} or a in {y} by XBOOLE_0:def 3;
      then a in Free H & not a in {z} & not a in {x} or a in {y} by A15,A17,
XBOOLE_0:def 5;
      then a in Free H \ {z} & not a in {x} or a in {y} by XBOOLE_0:def 5;
      then a in (Free H \ {z}) \ {x} or a in {y} by XBOOLE_0:def 5;
      hence thesis by XBOOLE_0:def 3;
    end;
    assume P[H];
    then
A18: Free (H/(x,y)) \ {s} c= ((Free H \ {x}) \/ {y}) \ {s} by XBOOLE_1:33;
A19: Free All(s,H/(x,y)) = Free (H/(x,y)) \ {s} by ZF_LANG1:62;
    All(z,H)/(x,y) = All(s,H/(x,y)) by A15,ZF_LANG1:159,160;
    hence thesis by A19,A14,A18,A16,XBOOLE_1:1;
  end;
A20: for H st P[H] holds P['not' H]
  proof
    let H;
A21: Free 'not' H = Free H by ZF_LANG1:60;
    Free 'not'(H/(x,y)) = Free (H/(x,y)) by ZF_LANG1:60;
    hence thesis by A21,ZF_LANG1:156;
  end;
  for H holds P[H] from ZF_LANG1:sch 1(A1,A20,A6,A13);
  hence thesis;
end;
