reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th20:
  for o being OperSymbol of S st
  o = In((the connectives of S).10, the carrier' of S)
  holds the_arity_of o = <*I,I*> & the_result_sort_of o = the bool-sort of S
  proof
    let o be OperSymbol of S;
    assume A1: o = In((the connectives of S).10, the carrier' of S);
    4+6 <= len the connectives of S by AOFA_A00:def 39;
    then 10 in dom the connectives of S by FINSEQ_3:25;
    then o = (the connectives of S).10 by A1,FUNCT_1:102,SUBSET_1:def 8;
    then o is_of_type <*I,I*>, the bool-sort of S by AOFA_A00:53;
    hence the_arity_of o = <*I,I*> & the_result_sort_of o = the bool-sort of S;
  end;
