
theorem Th20:
  for X, Y being compact non empty TopSpace, F being Subset-Family
  of [:Y, X:] st F is Cover of [:Y, X:] & F is open ex G being Subset-Family of
  [:Y, X:] st G c= F & G is Cover of [:Y, X:] & G is finite
proof
  let X, Y be compact non empty TopSpace;
  let F be Subset-Family of [:Y, X:];
  set R = { Q where Q is open Subset of X : ex FQ being Subset-Family of [:Y,
  X:] st FQ c= F & FQ is finite & [:[#]Y, Q:] c= union FQ };
  R c= bool the carrier of X
  proof
    let s be object;
    assume s in R;
    then ex Q1 being open Subset of X st s = Q1 & ex FQ being Subset-Family of
    [:Y, X:] st FQ c= F & FQ is finite & [: [#]Y, Q1:] c= union FQ;
    hence thesis;
  end;
  then reconsider R as Subset-Family of X;
  reconsider R as Subset-Family of X;
  defpred P[object,object] means
  ex D1 being set, FQ being Subset-Family of [:Y, X:] st
    D1 = $1 & FQ c= F &
    FQ is finite & [:[#]Y, D1:] c= union FQ & $2 = FQ;
  deffunc F(set) = [:[#]Y, $1:];
  assume F is Cover of [:Y, X:] & F is open;
  then consider C being Subset-Family of X such that
A1: C c= R and
A2: C is finite and
A3: C is Cover of X by Th19;
  set CX = { F(f) where f is Subset of X : f in C };
  CX c= bool the carrier of [:Y, X:]
  proof
    let s be object;
    assume s in CX;
    then consider f1 being Subset of X such that
A4: s = F(f1) and
    f1 in C;
    [:[#]Y, f1:] c= the carrier of [:Y, X:];
    hence thesis by A4;
  end;
  then reconsider CX as Subset-Family of [:Y, X:];
  reconsider CX as Subset-Family of [:Y, X:];
A5: for e be object st e in C ex u be object st P[e,u]
  proof
    let e be object;
    assume e in C;
    then e in R by A1;
    then ex Q1 being open Subset of X st Q1 = e & ex FQ being Subset-Family of
    [:Y, X:] st FQ c= F & FQ is finite & [:[#]Y, Q1:] c= union FQ;
    hence thesis;
  end;
  consider t being Function such that
A6: dom t = C & for s being object st s in C holds P[s, t.s] from CLASSES1
  :sch 1(A5);
  set G = union rng t;
A7: union rng t c= F
  proof
    let k be object;
    assume k in union rng t;
    then consider K be set such that
A8: k in K and
A9: K in rng t by TARSKI:def 4;
    consider x1 be object such that
A10: x1 in dom t & K = t.x1 by A9,FUNCT_1:def 3;
    reconsider x1 as set by TARSKI:1;
    P[x1, t.x1] by A6,A10;
    then ex FQ being Subset-Family of [:Y, X:] st FQ c= F & FQ is finite & [:
    [#]Y, x1:] c= union FQ & K = FQ by A10;
    hence thesis by A8;
  end;
  G c= bool the carrier of [:Y, X:]
  proof
    let s be object;
    assume s in G;
    then s in F by A7;
    hence thesis;
  end;
  then reconsider G as Subset-Family of [:Y, X:];
  reconsider G as Subset-Family of [:Y, X:];
  take G;
  thus G c= F by A7;
  union CX = [:[#]Y, union C:]
  proof
    hereby
      let g be object;
      assume g in union CX;
      then consider GG being set such that
A11:  g in GG and
A12:  GG in CX by TARSKI:def 4;
      consider FF being Subset of X such that
A13:  GG = [:[#]Y, FF:] and
A14:  FF in C by A12;
      consider g1, g2 be object such that
A15:  g1 in [#]Y and
A16:  g2 in FF and
A17:  g = [g1, g2] by A11,A13,ZFMISC_1:def 2;
      g2 in union C by A14,A16,TARSKI:def 4;
      hence g in [:[#]Y, union C:] by A15,A17,ZFMISC_1:87;
    end;
    let g be object;
    assume g in [:[#]Y, union C:];
    then consider g1, g2 be object such that
A18: g1 in [#]Y and
A19: g2 in union C and
A20: g = [g1, g2] by ZFMISC_1:def 2;
    consider GG being set such that
A21: g2 in GG and
A22: GG in C by A19,TARSKI:def 4;
    GG in { Q where Q is open Subset of X : ex FQ being Subset-Family of
    [:Y, X:] st FQ c= F & FQ is finite & [:[#]Y, Q:] c= union FQ } by A1,A22;
    then consider Q1 being open Subset of X such that
A23: GG = Q1 and
    ex FQ being Subset-Family of [:Y, X:] st FQ c= F & FQ is finite & [:
    [#]Y, Q1:] c= union FQ;
A24: [:[#]Y, Q1:] in CX by A22,A23;
    g in [:[#]Y, Q1:] by A18,A20,A21,A23,ZFMISC_1:87;
    hence thesis by A24,TARSKI:def 4;
  end;
  then
A25: union CX = [:[#]Y, [#]X:] by A3,SETFAM_1:45
    .= [#][:Y, X:] by BORSUK_1:def 2;
  [#][:Y, X:] c= union union rng t
  proof
    let d be object;
    assume d in [#][:Y, X:];
    then consider CC being set such that
A26: d in CC and
A27: CC in CX by A25,TARSKI:def 4;
    consider Cc being Subset of X such that
A28: CC = [:[#]Y, Cc:] and
A29: Cc in C by A27;
    Cc in R by A1,A29;
    then consider Qq being open Subset of X such that
A30: Cc = Qq and
    ex FQ being Subset-Family of [:Y, X:] st FQ c= F & FQ is finite & [:
    [#]Y, Qq:] c= union FQ;
    P[Cc, t.Cc] by A6,A29;
    then consider FQ1 being Subset-Family of [:Y, X:] such that
    FQ1 c= F and
    FQ1 is finite and
A31: [:[#]Y, Qq:] c= union FQ1 and
A32: t.Qq = FQ1 by A30;
    consider DC being set such that
A33: d in DC and
A34: DC in FQ1 by A26,A28,A30,A31,TARSKI:def 4;
    FQ1 in rng t by A6,A29,A30,A32,FUNCT_1:def 3;
    then DC in union rng t by A34,TARSKI:def 4;
    hence thesis by A33,TARSKI:def 4;
  end;
  hence G is Cover of [:Y, X:] by SETFAM_1:def 11;
A35: for X1 be set st X1 in rng t holds X1 is finite
  proof
    let X1 be set;
    assume X1 in rng t;
    then consider x1 be object such that
A36: x1 in dom t and
A37: X1 = t.x1 by FUNCT_1:def 3;
    reconsider x1 as set by TARSKI:1;
    P[x1, t.x1] by A6,A36;
    then ex FQ being Subset-Family of [:Y, X:] st FQ c= F & FQ is finite & [:
    [#]Y, x1:] c= union FQ & t.x1 = FQ;
    hence thesis by A37;
  end;
  rng t is finite by A2,A6,FINSET_1:8;
  hence thesis by A35,FINSET_1:7;
end;
