reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  for z,u being Element of Y st G is independent & G={A,B,C} & A<>B & B
  <>C & C<>A & EqClass(z,C)=EqClass(u,C) holds EqClass(u,CompF(A,G)) meets
  EqClass(z,CompF(B,G))
proof
  let z,u be Element of Y;
  assume that
A1: G is independent and
A2: G={A,B,C} and
A3: A<>B and
A4: B<>C and
A5: C<>A and
A6: EqClass(z,C)=EqClass(u,C);
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (A .--> EqClass(z,
  A));
  A in dom (A .--> EqClass(z,A)) by TARSKI:def 1;
  then h.A = (A .--> EqClass(z,A)).A by FUNCT_4:13;
  then
A8: h.A = EqClass(z,A) by FUNCOP_1:72;
  set H=EqClass(z,CompF(B,G)), I=EqClass(z,A), GG=EqClass(u,B '/\' C);
A9: GG /\ I = EqClass(u,B) /\ EqClass(u,C) /\ EqClass(z,A) by Th1;
  dom ((B .--> EqClass(u,B)) +* (C .--> EqClass(u,C))) = dom (B .-->
  EqClass(u,B)) \/ dom (C .--> EqClass(u,C)) by FUNCT_4:def 1;
  then
A10: dom ((B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (A .--> EqClass(
z,A))) = dom (B .--> EqClass(u,B)) \/ dom (C .--> EqClass(u,C)) \/ dom (A .-->
  EqClass(z,A)) by FUNCT_4:def 1;
A12: C in dom (C .--> EqClass(u,C)) by TARSKI:def 1;
  not B in dom (A .--> EqClass(z,A)) by A3,TARSKI:def 1;
  then
A13: h.B=((B .--> EqClass(u,B)) +* (C .--> EqClass(u,C))).B by FUNCT_4:11;
  not B in dom (C .--> EqClass(u,C)) by A4,TARSKI:def 1;
  then h.B=(B .--> EqClass(u,B)).B by A13,FUNCT_4:11;
  then
A14: h.B = EqClass(u,B) by FUNCOP_1:72;
  not C in dom (A .--> EqClass(z,A)) by A5,TARSKI:def 1;
  then h.C=((B .--> EqClass(u,B)) +* (C .--> EqClass(u,C))).C by FUNCT_4:11;
  then h.C=(C .--> EqClass(u,C)).C by A12,FUNCT_4:13;
  then
A15: h.C = EqClass(u,C) by FUNCOP_1:72;
A16: dom ((B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (A .--> EqClass(
  z,A))) = {A} \/ {B} \/ {C} by A10,XBOOLE_1:4
    .= {A,B} \/ {C} by ENUMSET1:1
    .= {A,B,C} by ENUMSET1:3;
A17: rng h c= {h.A,h.B,h.C}
  proof
    let t be object;
    assume t in rng h;
    then consider x1 being object such that
A18: x1 in dom h and
A19: t = h.x1 by FUNCT_1:def 3;
    now
      per cases by A16,A18,ENUMSET1:def 1;
      case
        x1=A;
        hence thesis by A19,ENUMSET1:def 1;
      end;
      case
        x1=B;
        hence thesis by A19,ENUMSET1:def 1;
      end;
      case
        x1=C;
        hence thesis by A19,ENUMSET1:def 1;
      end;
    end;
    hence thesis;
  end;
  rng h c= bool Y
  proof
    let t be object;
    assume
A20: t in rng h;
    now
      per cases by A17,A20,ENUMSET1:def 1;
      case
        t=h.A;
        hence thesis by A8;
      end;
      case
        t=h.B;
        hence thesis by A14;
      end;
      case
        t=h.C;
        hence thesis by A15;
      end;
    end;
    hence thesis;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
A21: z in H by EQREL_1:def 6;
  for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume
A22: d in G;
    now
      per cases by A2,A22,ENUMSET1:def 1;
      case
        d=A;
        hence thesis by A8;
      end;
      case
        d=B;
        hence thesis by A14;
      end;
      case
        d=C;
        hence thesis by A15;
      end;
    end;
    hence thesis;
  end;
  then (Intersect FF)<>{} by A1,A2,A16,BVFUNC_2:def 5;
  then consider m being object such that
A23: m in Intersect FF by XBOOLE_0:def 1;
  A in dom h by A16,ENUMSET1:def 1;
  then
A24: h.A in rng h by FUNCT_1:def 3;
  then
A25: Intersect FF = meet (rng h) by SETFAM_1:def 9;
  C in dom h by A16,ENUMSET1:def 1;
  then h.C in rng h by FUNCT_1:def 3;
  then
A26: m in h.C by A25,A23,SETFAM_1:def 1;
  B in dom h by A16,ENUMSET1:def 1;
  then h.B in rng h by FUNCT_1:def 3;
  then m in h.B by A25,A23,SETFAM_1:def 1;
  then
A27: m in EqClass(u,B) /\ EqClass(u,C) by A14,A15,A26,XBOOLE_0:def 4;
  m in h.A by A24,A25,A23,SETFAM_1:def 1;
  then GG /\ I <> {} by A8,A9,A27,XBOOLE_0:def 4;
  then consider p being object such that
A28: p in GG /\ I by XBOOLE_0:def 1;
  reconsider p as Element of Y by A28;
  set K=EqClass(p,C);
A29: I /\ K in INTERSECTION(A,C) by SETFAM_1:def 5;
  set L=EqClass(z,C);
A30: p in EqClass(p,C) by EQREL_1:def 6;
A31: p in GG by A28,XBOOLE_0:def 4;
  p in K & p in I by A28,EQREL_1:def 6,XBOOLE_0:def 4;
  then
A32: p in I /\ K by XBOOLE_0:def 4;
  then not I /\ K in {{}} by TARSKI:def 1;
  then I /\ K in INTERSECTION(A,C) \ {{}} by A29,XBOOLE_0:def 5;
  then
A33: I /\ K in A '/\' C by PARTIT1:def 4;
  GG c= L by A6,BVFUNC11:3;
  then K meets L by A31,A30,XBOOLE_0:3;
  then K=L by EQREL_1:41;
  then
A34: z in K by EQREL_1:def 6;
  z in I by EQREL_1:def 6;
  then
A35: z in I /\ K by A34,XBOOLE_0:def 4;
  CompF(B,G) = A '/\' C by A2,A3,A4,Th5;
  then
A36: I /\ K = H or I /\ K misses H by A33,EQREL_1:def 4;
  GG=EqClass(u,CompF(A,G)) by A2,A3,A5,Th4;
  hence thesis by A32,A31,A35,A21,A36,XBOOLE_0:3;
end;
