reserve x,X,X2,Y,Y2 for set;
reserve GX for non empty TopSpace;
reserve A2,B2 for Subset of GX;
reserve B for Subset of GX;

theorem Th20:
  for A being Subset of GX st A=(the carrier of GX) holds A is
  a_union_of_components of GX
proof
  let A be Subset of GX;
  {B : B is a_component} c= bool (the carrier of GX)
  proof
    let x be object;
    assume x in {B : B is a_component};
    then ex B being Subset of GX st x=B & B is a_component;
    hence thesis;
  end;
  then reconsider S={B: B is a_component} as Subset-Family of GX;
A1: for B being Subset of GX st B in S holds B is a_component
  proof
    let B be Subset of GX;
    assume B in S;
    then ex B2 being Subset of GX st B=B2 & B2 is a_component;
    hence thesis;
  end;
  the carrier of GX c= union S
  proof
    let x be object;
    assume x in the carrier of GX;
    then reconsider p=x as Point of GX;
    set B3=Component_of p;
    B3 is a_component by CONNSP_1:40;
    then p in Component_of p & B3 in S by CONNSP_1:38;
    hence thesis by TARSKI:def 4;
  end;
  then
A2: the carrier of GX=union S;
  assume A=(the carrier of GX);
  hence thesis by A2,A1,Def2;
end;
