reserve MS for OrtAfPl;
reserve MP for OrtAfSp;
reserve V for RealLinearSpace;
reserve w,y,u,v for VECTOR of V;

theorem Th20:
  Gen w,y & MS = AMSpace(V,w,y) implies MS is satisfying_LIN
proof
  assume that
A1: Gen w,y and
A2: MS=AMSpace(V,w,y);
  now
    let o,a,a1,b,b1,c,c1 be Element of MS such that
A3: o<>a and
    o<>a1 and
A4: o<>b and
    o<>b1 and
A5: o<>c and
A6: o<>c1 and
    a<>b and
A7: o,c _|_ o,c1 and
A8: o,a _|_ o,a1 and
A9: o,b _|_ o,b1 and
A10: not LIN o,c,a and
A11: LIN o,a,b and
    LIN o,a1,b1 and
A12: a,c _|_ a1,c1 and
A13: b,c _|_ b1,c1;
    reconsider q=o,u1=a,u2=b,u3=c,v3=c1 as VECTOR of V by A2,ANALMETR:19;
    consider A1,A2 being Real such that
A14: u1-q=A1*w+A2*y by A1,ANALMETR:def 1;
    reconsider A1,A2 as Real;
A15: not LIN o,c,b
    proof
      reconsider o9=o,a9=a,b9=b,c9=c as Element of the AffinStruct of MS;
      assume LIN o,c,b;
      then LIN o9,c9,b9 by ANALMETR:40;
      then
A16:  LIN o9,b9,c9 by AFF_1:6;
      LIN o9,a9,b9 by A11,ANALMETR:40;
      then
A17:  LIN o9,b9,a9 by AFF_1:6;
      LIN o9,b9,o9 by AFF_1:7;
      then LIN o9,c9,a9 by A4,A16,A17,AFF_1:8;
      hence contradiction by A10,ANALMETR:40;
    end;
    q,u3,q,v3 are_Ort_wrt w,y by A2,A7,ANALMETR:21;
    then
A18: u3-q,v3-q are_Ort_wrt w,y by ANALMETR:def 3;
    u3-q<>0.V & v3-q<>0.V by A5,A6,RLVECT_1:21;
    then consider r being Real such that
A19: for a9,b9 being Real holds a9*w+b9*y,(r*b9)*w+(-r*a9)*y
are_Ort_wrt w,y & (a9*w+b9*y)-(u3-q),((r*b9)*w+(-r*a9)*y)-(v3-q) are_Ort_wrt w,
    y by A1,A18,Th19;
    o,a // o,b by A11,ANALMETR:def 10;
    then q,u1 '||' q,u2 by A2,GEOMTRAP:4;
    then q,u1 // q,u2 or q,u1 // u2,q by GEOMTRAP:def 1;
    then consider a9,b9 being Real such that
A20: a9*(u1-q)=b9*(u2-q) and
A21: a9<>0 or b9<>0 by ANALMETR:14;
    consider B1,B2 being Real such that
A22: u2-q=B1*w+B2*y by A1,ANALMETR:def 1;
    reconsider a9,b9,B1,B2 as Real;
    set s=b9"*a9;
A23: u1-q<>0.V by A3,RLVECT_1:21;
    now
      assume
A24:  b9=0;
      then 0.V = a9*(u1-q) by A20,RLVECT_1:10;
      hence contradiction by A23,A21,A24,RLVECT_1:11;
    end;
    then
A25: u2-q = b9"*(a9*(u1-q)) by A20,ANALOAF:5
      .= s*(u1-q) by RLVECT_1:def 7;
    then B1*w+B2*y = s*(A1*w)+s*(A2*y) by A14,A22,RLVECT_1:def 5
      .= (s*A1)*w + s*(A2*y) by RLVECT_1:def 7
      .= (s*A1)*w+(s*A2)*y by RLVECT_1:def 7;
    then
A26: B1=s*A1 & B2=s*A2 by A1,Lm7;
    set v19=((r*A2)*w+(-r*A1)*y)+q,v29=((r*B2)*w+(-r*B1)*y)+q;
    reconsider a19=v19,b19=v29 as Element of MS by A2,ANALMETR:19;
A27: v29-q = (r*B2)*w+(-r*B1)*y by RLSUB_2:61
      .= (r*B2)*w+(r*B1)*(-y) by RLVECT_1:24
      .= (r*(s*A2))*w - (r*(s*A1))*y by A26,RLVECT_1:25
      .= r*((s*A2)*w) - (r*(s*A1))*y by RLVECT_1:def 7
      .= r*((s*A2)*w) - r*((s*A1)*y) by RLVECT_1:def 7
      .= r*((s*A2)*w - (s*A1)*y) by RLVECT_1:34
      .= r*(s*(A2*w) - (s*A1)*y) by RLVECT_1:def 7
      .= r*(s*(A2*w) - s*(A1*y)) by RLVECT_1:def 7
      .= r*(s*(A2*w - A1*y)) by RLVECT_1:34
      .= (s*r)*(A2*w - A1*y) by RLVECT_1:def 7
      .= s*(r*(A2*w - A1*y)) by RLVECT_1:def 7
      .= s*(r*(A2*w) - r*(A1*y)) by RLVECT_1:34
      .= s*((r*A2)*w - r*(A1*y)) by RLVECT_1:def 7
      .= s*((r*A2)*w + - (r*A1)*y) by RLVECT_1:def 7
      .= s*( (r*A2)*w + (r*A1)*(-y)) by RLVECT_1:25
      .= s*((r*A2)*w + (-r*A1)*y) by RLVECT_1:24
      .= s*(v19-q) by RLSUB_2:61;
A28: v29-q=(r*B2)*w+(-r*B1)*y by RLSUB_2:61;
    then u2-q,v29-q are_Ort_wrt w,y by A19,A22;
    then q,u2,q,v29 are_Ort_wrt w,y by ANALMETR:def 3;
    then
A29: o,b _|_ o,b19 by A2,ANALMETR:21;
    1*(u2-v29) = u2-v29 by RLVECT_1:def 8
      .= s*(u1-q)-s*(v19-q) by A25,A27,Lm4
      .= s*((u1-q)-(v19-q)) by RLVECT_1:34
      .= s*(u1-v19) by Lm4;
    then v19,u1 // v29,u2 or v19,u1 // u2,v29 by ANALMETR:14;
    then v19,u1 '||' v29,u2 by GEOMTRAP:def 1;
    then
A30: a19,a // b19,b by A2,GEOMTRAP:4;
A31: v19-q=(r*A2)*w+(-r*A1)*y by RLSUB_2:61;
    then u1-q,v19-q are_Ort_wrt w,y by A19,A14;
    then q,u1,q,v19 are_Ort_wrt w,y by ANALMETR:def 3;
    then
A32: o,a _|_ o,a19 by A2,ANALMETR:21;
    (u2-q)-(u3-q)=u2-u3 & (v29-q)-(v3-q)=v29-v3 by Lm4;
    then u2-u3,v29-v3 are_Ort_wrt w,y by A19,A22,A28;
    then u3,u2,v3,v29 are_Ort_wrt w,y by ANALMETR:def 3;
    then
A33: c,b _|_ c1,b19 by A2,ANALMETR:21;
    c,b _|_ c1,b1 by A13,ANALMETR:61;
    then
A34: b1=b19 by A6,A7,A9,A15,A29,A33,Th16;
    (u1-q)-(u3-q)=u1-u3 & (v19-q)-(v3-q)=v19-v3 by Lm4;
    then u1-u3,v19-v3 are_Ort_wrt w,y by A19,A14,A31;
    then u3,u1,v3,v19 are_Ort_wrt w,y by ANALMETR:def 3;
    then
A35: c,a _|_ c1,a19 by A2,ANALMETR:21;
    c,a _|_ c1,a1 by A12,ANALMETR:61;
    then a1=a19 by A6,A7,A8,A10,A32,A35,Th16;
    hence a,a1 // b,b1 by A34,A30,ANALMETR:59;
  end;
  hence thesis by CONAFFM:def 5;
end;
