reserve y for set,
  x,a for Real,
  n for Element of NAT,
  Z for open Subset of REAL,
  f,f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (ln*(exp_R+f)) & (for x st x in Z holds f.x=1 ) implies ln*(
exp_R+f) is_differentiable_on Z & for x st x in Z holds ((ln*(exp_R+f))`|Z).x =
  exp_R.x/(exp_R.x+1)
proof
  assume that
A1: Z c= dom (ln*(exp_R+f)) and
A2: for x st x in Z holds f.x=1;
A3: for x st x in Z holds f.x=0*x+1 by A2;
  for y being object st y in Z holds y in dom (exp_R+f) by A1,FUNCT_1:11;
  then
A4: Z c= dom (exp_R+f) by TARSKI:def 3;
  then Z c= dom exp_R /\ dom f by VALUED_1:def 1;
  then
A5: Z c= dom f by XBOOLE_1:18;
  then
A6: f is_differentiable_on Z by A3,FDIFF_1:23;
A7: exp_R is_differentiable_on Z by FDIFF_1:26,TAYLOR_1:16;
  then
A8: exp_R+f is_differentiable_on Z by A4,A6,FDIFF_1:18;
A9: for x st x in Z holds ((exp_R+f)`|Z).x =exp_R.x
  proof
    let x;
    assume
A10: x in Z;
    hence ((exp_R+f)`|Z).x = diff(exp_R,x) + diff(f,x) by A4,A6,A7,FDIFF_1:18
      .=exp_R.x+ diff(f,x) by SIN_COS:65
      .=exp_R.x+(f`|Z).x by A6,A10,FDIFF_1:def 7
      .=exp_R.x+0 by A5,A3,A10,FDIFF_1:23
      .=exp_R.x;
  end;
A11: for x st x in Z holds (exp_R+f).x>0
  proof
    let x;
    assume
A12: x in Z;
    then (exp_R+f).x=exp_R.x + f.x by A4,VALUED_1:def 1
      .=exp_R.x +1 by A2,A12;
    hence thesis by SIN_COS:54,XREAL_1:34;
  end;
A13: for x st x in Z holds ln*(exp_R+f) is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then exp_R+f is_differentiable_in x & (exp_R+f).x >0 by A8,A11,FDIFF_1:9;
    hence thesis by TAYLOR_1:20;
  end;
  then
A14: ln*(exp_R+f) is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((ln*(exp_R+f))`|Z).x = exp_R.x/(exp_R.x+1)
  proof
    let x;
    assume
A15: x in Z;
    then
A16: (exp_R+f).x=exp_R.x + f.x by A4,VALUED_1:def 1
      .=exp_R.x +1 by A2,A15;
    exp_R+f is_differentiable_in x & (exp_R+f).x>0 by A8,A11,A15,FDIFF_1:9;
    then diff(ln*(exp_R+f),x) =diff((exp_R+f),x)/((exp_R+f).x) by TAYLOR_1:20
      .=((exp_R+f)`|Z).x/((exp_R+f).x) by A8,A15,FDIFF_1:def 7
      .=exp_R.x/(exp_R.x +1) by A9,A15,A16;
    hence thesis by A14,A15,FDIFF_1:def 7;
  end;
  hence thesis by A1,A13,FDIFF_1:9;
end;
