reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (( #Z n)*tan) & 1<=n implies ( #Z n)*tan is_differentiable_on
Z & for x st x in Z holds ((( #Z n)*tan)`|Z).x =n*(sin.x) #Z (n-1)/(cos.x) #Z (
  n+1)
proof
  assume that
A1: Z c= dom (( #Z n)*tan) and
A2: 1<=n;
A3: dom (( #Z n)*tan) c= dom tan by RELAT_1:25;
A4: for x st x in Z holds cos.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom (sin/cos) by A1,FUNCT_1:11;
    hence thesis by Th1;
  end;
A5: for x st x in Z holds ( #Z n)*tan is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A4;
    then tan is_differentiable_in x by FDIFF_7:46;
    hence thesis by TAYLOR_1:3;
  end;
  then
A6: ( #Z n)*tan is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((( #Z n)*tan)`|Z).x =n*((sin.x) #Z (n-1))/(cos.x
  ) #Z (n+1)
  proof
    set m = n-1;
    let x;
A7: ex m being Nat st n = m + 1 by A2,NAT_1:6;
    assume
A8: x in Z;
    then
A9: cos.x<>0 by A4;
    then
A10: tan is_differentiable_in x by FDIFF_7:46;
    ((( #Z n)*tan)`|Z).x=diff(( #Z n)*tan,x) by A6,A8,FDIFF_1:def 7
      .=n*(tan.x) #Z (n-1) * diff(tan,x) by A10,TAYLOR_1:3
      .=n*(tan.x) #Z (n-1) *(1/(cos.x)^2) by A9,FDIFF_7:46
      .=n*((sin.x) #Z m /(cos.x) #Z m)/(cos.x)^2 by A1,A3,A8,A7,Th3,XBOOLE_1:1
      .=n*(sin.x) #Z (n-1)/(cos.x) #Z (n-1)/(cos.x)^2
      .=n*(sin.x) #Z (n-1)/((cos.x) #Z (n-1)*(cos.x)^2) by XCMPLX_1:78
      .=n*((sin.x) #Z (n-1))/((cos.x) #Z (n-1)*(cos.x) #Z 2) by FDIFF_7:1
      .=n*((sin.x) #Z (n-1))/((cos.x) #Z (n-1+2)) by A4,A8,PREPOWER:44
      .=n*((sin.x) #Z (n-1))/(cos.x) #Z (n+1);
    hence thesis;
  end;
  hence thesis by A1,A5,FDIFF_1:9;
end;
