 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;
reserve n for non zero Nat;

theorem
  for F being non almost_trivial Field holds
  ex K being non polynomial_disjoint Field, p being Polynomial of K
  st K,F are_isomorphic & deg p = n & p in [#]K /\ [#]Polynom-Ring K
  proof
    let F be non almost_trivial Field;
    set x = the non trivial Element of F;
    reconsider n as Element of NAT by ORDINAL1:def 12;
    reconsider o = rpoly(n,0.F) as object;
    set x = the non trivial Element of F;
    per cases;
      suppose
A1:     not o in [#]F; then
        reconsider K = ExField(x,rpoly(n,0.F)) as Field
          by Th7,Th8,Th10,Th9,Th12,Th11;
        set p = rpoly(n,0.K);
        now let i be Element of NAT;
          per cases;
            suppose
A2:           i = 0;
              hence rpoly(n,0.F).i = -power(F).(0.F,n) by HURWITZ:25
              .= -0.F by Th6
              .= -0.K by Def8
              .= -power(K).(0.K,n) by Th6
              .= p.i by A2,HURWITZ:25;
            end;
            suppose
A3:           i = n;
              hence rpoly(n,0.F).i = 1_F by HURWITZ:25
              .= 1_K by Def8
              .= p.i by A3,HURWITZ:25;
            end;
            suppose
A4:           i <> 0 & i <> n;
              hence rpoly(n,0.F).i = 0.F by HURWITZ:26
              .= 0.K by Def8
              .= p.i by A4,HURWITZ:26;
            end;
          end; then
A5:       rpoly(n,0.F) = rpoly(n,0.K);
A6:       p in [#]Polynom-Ring K by POLYNOM3:def 10;
          p in {rpoly(n,0.F)} by A5,TARSKI:def 1; then
          p in carr(x,rpoly(n,0.F)) by XBOOLE_0:def 3; then
A7:       p in [#]K by Def8; then
          p in [#]K /\ [#]Polynom-Ring K by A6,XBOOLE_0:def 4; then
          reconsider K as non polynomial_disjoint Field by Def3;
          take K;
          take p = rpoly(n,0.K);
          isoR(x,rpoly(n,0.F)) is
          additive multiplicative unity-preserving by A1,Th15;
          hence K,F are_isomorphic by MOD_4:def 12,QUOFIELD:def 23;
          thus thesis by A7,A6,XBOOLE_0:def 4,HURWITZ:27;
        end;
        suppose
A8:       ex a being Element of F st a = rpoly(n,0.F); then
          consider a being Element of F such that
A9:       a = rpoly(n,0.F);
          a in the carrier of Polynom-Ring(F) by A9,POLYNOM3:def 10; then
          a in [#]F /\ [#]Polynom-Ring(F) by XBOOLE_0:def 4;then
          reconsider K = F as non polynomial_disjoint Field by Def3;
          take K;
          take x = rpoly(n,0.K);
          x in the carrier of Polynom-Ring F by POLYNOM3:def 10;
          hence thesis by A8,HURWITZ:27,XBOOLE_0:def 4;
        end;
      end;
