reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th20:
  1 <= j & j < width G implies Int cell(G,0,j) = { |[r,s]| : r < G
  *(1,1)`1 & G*(1,j)`2 < s & s < G*(1,j+1)`2 }
proof
  cell(G,0,j) = v_strip(G,0) /\ h_strip(G,j) by GOBOARD5:def 3;
  then
A1: Int cell(G,0,j) = Int v_strip(G,0) /\ Int h_strip(G,j) by TOPS_1:17;
  assume 1 <= j & j < width G;
  then
A2: Int h_strip(G,j) = { |[r,s]| : G*(1,j)`2 < s & s < G* (1,j+1)`2 } by Th17;
A3: Int v_strip(G,0) = { |[r,s]| : r < G*(1,1)`1 } by Th12;
  thus Int cell(G,0,j) c= { |[r,s]| : r < G*(1,1)`1 & G*(1,j)`2 < s & s < G*(1
  ,j+1)`2 }
  proof
    let x be object;
    assume
A4: x in Int cell(G,0,j);
    then x in Int v_strip(G,0) by A1,XBOOLE_0:def 4;
    then consider r1,s1 such that
A5: x = |[r1,s1]| and
A6: r1 < G*(1,1)`1 by A3;
    x in Int h_strip(G,j) by A1,A4,XBOOLE_0:def 4;
    then consider r2,s2 such that
A7: x = |[r2,s2]| and
A8: G*(1,j)`2 < s2 & s2 < G*(1,j+1)`2 by A2;
    s1 = s2 by A5,A7,SPPOL_2:1;
    hence thesis by A5,A6,A8;
  end;
  let x be object;
  assume x in { |[r,s]| : r < G*(1,1)`1 & G*(1,j)`2 < s & s < G*(1,j+1)`2 };
  then
A9: ex r,s st x = |[r,s]| & r < G*(1,1)`1 & G*(1,j)`2 < s & s < G*(1,j+1)`2;
  then
A10: x in Int h_strip(G,j) by A2;
  x in Int v_strip(G,0) by A3,A9;
  hence thesis by A1,A10,XBOOLE_0:def 4;
end;
