reserve i, j, k, n for Nat,
  P for Subset of TOP-REAL 2,
  C for connected compact non vertical non horizontal Subset of TOP-REAL 2;

theorem Th20:
  COMPLEMENT UBD-Family C = BDD-Family C
proof
  for P being Subset of TOP-REAL 2 holds P in BDD-Family C iff P` in
  UBD-Family C
  proof
    let P being Subset of TOP-REAL 2;
    thus P in BDD-Family C implies P` in UBD-Family C
    proof
      assume P in BDD-Family C;
      then consider k such that
A1:   P = Cl BDD L~Cage(C,k);
      P = Cl RightComp Cage(C,k) by A1,GOBRD14:37;
      then
A2:   P = (RightComp Cage(C,k)) \/ L~Cage(C,k) by GOBRD14:21;
      P` /\ (LeftComp Cage(C,k))` = (P \/ LeftComp Cage(C,k))` by XBOOLE_1:53
        .= ([#]the carrier of TOP-REAL 2)` by A2,GOBRD14:15
        .= {}the carrier of TOP-REAL 2 by XBOOLE_1:37;
      then
A3:   P` misses (LeftComp Cage(C,k))`;
      L~Cage(C,k) misses LeftComp Cage(C,k) & RightComp Cage(C,k) misses
      LeftComp Cage(C,k) by GOBRD14:14,SPRECT_3:26;
      then P misses LeftComp Cage(C,k) by A2,XBOOLE_1:70;
      then P` = LeftComp Cage(C,k) by A3,SUBSET_1:25;
      then P` = UBD L~Cage(C,k) by GOBRD14:36;
      hence thesis;
    end;
    assume P` in UBD-Family C;
    then consider k such that
A4: P` = UBD L~Cage(C,k);
A5: P` = LeftComp Cage(C,k) by A4,GOBRD14:36;
    then P` misses RightComp Cage(C,k) & P` misses L~Cage(C,k) by GOBRD14:14
,SPRECT_3:26;
    then P` misses (RightComp Cage(C,k)) \/ L~Cage(C,k) by XBOOLE_1:70;
    then
A6: P` misses Cl RightComp Cage(C,k) by GOBRD14:21;
    P`` /\ (Cl RightComp Cage(C,k))` = (P` \/ (Cl RightComp Cage(C,k)))`
    by XBOOLE_1:53
      .= (P` \/ ((RightComp Cage(C,k)) \/ L~Cage(C,k)))` by GOBRD14:21
      .= ([#]the carrier of TOP-REAL 2)` by A5,GOBRD14:15
      .= {}the carrier of TOP-REAL 2 by XBOOLE_1:37;
    then P`` misses (Cl RightComp Cage(C,k))`;
    then P`` = Cl RightComp Cage(C,k) by A6,SUBSET_1:25;
    then P = Cl BDD L~Cage(C,k) by GOBRD14:37;
    hence thesis;
  end;
  hence thesis by SETFAM_1:def 7;
end;
