reserve n for Nat;

theorem Th20:
  for C be Simple_closed_curve for i1,i2,j,k be Nat st
  1 < i1 & i1 <= i2 & i2 < len Gauge(C,n) &
  1 <= j & j <= k & k <= width Gauge(C,n) &
  (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/
  LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) /\ L~Upper_Seq(C,n) =
  {Gauge(C,n)*(i1,j)} & (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/
  LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) /\ L~Lower_Seq(C,n) =
  {Gauge(C,n)*(i2,k)} holds (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/
  LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) meets Upper_Arc C
proof
  let C be Simple_closed_curve;
  let i1,i2,j,k be Nat;
  set G = Gauge(C,n);
  set pio = LSeg(G*(i1,j),G*(i1,k));
  set poz = LSeg(G*(i1,k),G*(i2,k));
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  assume that
A1: 1 < i1 and
A2: i1 <= i2 and
A3: i2 < len G and
A4: 1 <= j and
A5: j <= k and
A6: k <= width G and
A7: (pio \/ poz) /\ L~US = {G*(i1,j)} and
A8: (pio \/ poz) /\ L~LS = {G*(i2,k)} and
A9: (pio \/ poz) misses Upper_Arc C;
  set UA = Upper_Arc C;
  set Wmin = W-min L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Ebo = E-bound L~Cage(C,n);
  set Gik = G*(i2,k);
  set Gij = G*(i1,j);
  set Gi1k = G*(i1,k);
A10: i1 < len G by A2,A3,XXREAL_0:2;
A11: 1 < i2 by A1,A2,XXREAL_0:2;
A12: L~<*Gij,Gi1k,Gik*> = poz \/ pio by TOPREAL3:16;
  Gik in {Gik} by TARSKI:def 1;
  then
A13: Gik in L~LS by A8,XBOOLE_0:def 4;
  Gij in {Gij} by TARSKI:def 1;
  then
A14: Gij in L~US by A7,XBOOLE_0:def 4;
A15: j <= width G by A5,A6,XXREAL_0:2;
A16: 1 <= k by A4,A5,XXREAL_0:2;
A17: [i1,j] in Indices G by A1,A4,A10,A15,MATRIX_0:30;
A18: [i2,k] in Indices G by A3,A6,A11,A16,MATRIX_0:30;
A19: [i1,k] in Indices G by A1,A6,A10,A16,MATRIX_0:30;
  set go = R_Cut(US,Gij);
  set co = L_Cut(LS,Gik);
A20: len G = width G by JORDAN8:def 1;
A21: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A22: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
A23: Wmin`1 = Wbo
    .= G*(1,k)`1 by A6,A16,A20,JORDAN1A:73;
  len G >= 4 by JORDAN8:10;
  then
A24: len G >= 1 by XXREAL_0:2;
  then
A25: [1,k] in Indices G by A6,A16,MATRIX_0:30;
  then
A26: Gij <> US.1 by A1,A17,A22,A23,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2
  by A14,JORDAN3:35;
A27: [1,j] in Indices G by A4,A15,A24,MATRIX_0:30;
A28: len LS >= 1+2 by JORDAN1E:15;
  then
A29: len LS >= 1 by XXREAL_0:2;
  then
A30: 1 in dom LS by FINSEQ_3:25;
  len LS in dom LS by A29,FINSEQ_3:25;
  then
A31: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
  Wmin`1 = Wbo
    .= G*(1,k)`1 by A6,A16,A20,JORDAN1A:73;
  then
A32: Gik <> LS.len LS by A1,A2,A18,A25,A31,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2
  by A13,JORDAN3:34;
A33: [len G,k] in Indices G by A6,A16,A24,MATRIX_0:30;
A34: LS.1 = LS/.1 by A30,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  Emax`1 = Ebo
    .= G*(len G,k)`1 by A6,A16,A20,JORDAN1A:71;
  then
A35: Gik <> LS.1 by A3,A18,A33,A34,JORDAN1G:7;
A36: len go >= 1+1 by TOPREAL1:def 8;
A37: Gij in rng US by A1,A4,A10,A14,A15,JORDAN1G:4,JORDAN1J:40;
  then
A38: go is_sequence_on G by JORDAN1G:4,JORDAN1J:38;
A39: len co >= 1+1 by TOPREAL1:def 8;
A40: Gik in rng LS by A3,A6,A11,A13,A16,JORDAN1G:5,JORDAN1J:40;
  then
A41: co is_sequence_on G by JORDAN1G:5,JORDAN1J:39;
  reconsider go as non constant s.c.c.
  being_S-Seq FinSequence of TOP-REAL 2 by A36,A38,JGRAPH_1:12,JORDAN8:5;
  reconsider co as non constant s.c.c.
  being_S-Seq FinSequence of TOP-REAL 2 by A39,A41,JGRAPH_1:12,JORDAN8:5;
A42: len go > 1 by A36,NAT_1:13;
  then
A43: len go in dom go by FINSEQ_3:25;
  then
A44: go/.len go = go.len go by PARTFUN1:def 6
    .= Gij by A14,JORDAN3:24;
  len co >= 1 by A39,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A45: co/.1 = co.1 by PARTFUN1:def 6
    .= Gik by A13,JORDAN3:23;
  reconsider m = len go - 1 as Nat by A43,FINSEQ_3:26;
A46: m+1 = len go;
  then
A47: len go-'1 = m by NAT_D:34;
A48: LSeg(go,m) c= L~go by TOPREAL3:19;
A49: L~go c= L~US by A14,JORDAN3:41;
  then LSeg(go,m) c= L~US by A48;
  then
A50: LSeg(go,m) /\ L~<*Gij,Gi1k,Gik*> c= {Gij} by A7,A12,XBOOLE_1:26;
  m >= 1 by A36,XREAL_1:19;
  then
A51: LSeg(go,m) = LSeg(go/.m,Gij) by A44,A46,TOPREAL1:def 3;
  {Gij} c= LSeg(go,m) /\ L~<*Gij,Gi1k,Gik*>
  proof
    let x be object;
    assume x in {Gij};
    then
A52: x = Gij by TARSKI:def 1;
A53: Gij in LSeg(go,m) by A51,RLTOPSP1:68;
    Gij in LSeg(Gij,Gi1k) by RLTOPSP1:68;
    then Gij in LSeg(Gij,Gi1k) \/ LSeg(Gi1k,Gik) by XBOOLE_0:def 3;
    then Gij in L~<*Gij,Gi1k,Gik*> by SPRECT_1:8;
    hence thesis by A52,A53,XBOOLE_0:def 4;
  end;
  then
A54: LSeg(go,m) /\ L~<*Gij,Gi1k,Gik*> = {Gij} by A50;
A55: LSeg(co,1) c= L~co by TOPREAL3:19;
A56: L~co c= L~LS by A13,JORDAN3:42;
  then LSeg(co,1) c= L~LS by A55;
  then
A57: LSeg(co,1) /\ L~<*Gij,Gi1k,Gik*> c= {Gik} by A8,A12,XBOOLE_1:26;
A58: LSeg(co,1) = LSeg(Gik,co/.(1+1)) by A39,A45,TOPREAL1:def 3;
  {Gik} c= LSeg(co,1) /\ L~<*Gij,Gi1k,Gik*>
  proof
    let x be object;
    assume x in {Gik};
    then
A59: x = Gik by TARSKI:def 1;
A60: Gik in LSeg(co,1) by A58,RLTOPSP1:68;
    Gik in LSeg(Gi1k,Gik) by RLTOPSP1:68;
    then Gik in LSeg(Gij,Gi1k) \/ LSeg(Gi1k,Gik) by XBOOLE_0:def 3;
    then Gik in L~<*Gij,Gi1k,Gik*> by SPRECT_1:8;
    hence thesis by A59,A60,XBOOLE_0:def 4;
  end;
  then
A61: L~<*Gij,Gi1k,Gik*> /\ LSeg(co,1) = {Gik} by A57;
A62: go/.1 = US/.1 by A14,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A63: go/.1 = LS/.len LS by JORDAN1F:8
    .= co/.len co by A13,JORDAN1J:35;
A64: rng go c= L~go by A36,SPPOL_2:18;
A65: rng co c= L~co by A39,SPPOL_2:18;
A66: {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A67: x = go/.1 by TARSKI:def 1;
    then
A68: x in rng go by FINSEQ_6:42;
    x in rng co by A63,A67,FINSEQ_6:168;
    hence thesis by A64,A65,A68,XBOOLE_0:def 4;
  end;
A69: LS.1 = LS/.1 by A30,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A70: [len G,j] in Indices G by A4,A15,A24,MATRIX_0:30;
  L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A71: x in L~go /\ L~co;
    then
A72: x in L~go by XBOOLE_0:def 4;
A73: x in L~co by A71,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A49,A56,A72,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then
A74: x = Wmin or x = Emax by TARSKI:def 2;
    now
      assume x = Emax;
      then
A75:  Emax = Gik by A13,A69,A73,JORDAN1E:7;
      G*(len G,j)`1 = Ebo by A4,A15,A20,JORDAN1A:71;
      then Emax`1 <> Ebo by A3,A18,A70,A75,JORDAN1G:7;
      hence contradiction;
    end;
    hence thesis by A62,A74,TARSKI:def 1;
  end;
  then
A76: L~go /\ L~co = {go/.1} by A66;
  set W2 = go/.2;
A77: 2 in dom go by A36,FINSEQ_3:25;
A78: now
    assume Gij`1 = Wbo;
    then G*(1,j)`1 = G*(i1,j)`1 by A4,A15,A20,JORDAN1A:73;
    hence contradiction by A1,A17,A27,JORDAN1G:7;
  end;
  go = mid(US,1,Gij..US) by A37,JORDAN1G:49
    .= US|(Gij..US) by A37,FINSEQ_4:21,FINSEQ_6:116;
  then
A79: W2 = US/.2 by A77,FINSEQ_4:70;
A80: Wmin in rng go by A62,FINSEQ_6:42;
  set pion = <*Gij,Gi1k,Gik*>;
A81: now
    let n be Nat;
    assume n in dom pion;
    then n in {1,2,3} by FINSEQ_1:89,FINSEQ_3:1;
    then n = 1 or n = 2 or n = 3 by ENUMSET1:def 1;
    hence
    ex i,j be Nat st [i,j] in Indices G & pion/.n = G*(i,j)
    by A17,A18,A19,FINSEQ_4:18;
  end;
A82: Gi1k`1 = G*(i1,1)`1 by A1,A6,A10,A16,GOBOARD5:2
    .= Gij`1 by A1,A4,A10,A15,GOBOARD5:2;
  Gi1k`2 = G*(1,k)`2 by A1,A6,A10,A16,GOBOARD5:1
    .= Gik`2 by A3,A6,A11,A16,GOBOARD5:1;
  then
A83: Gi1k = |[Gij`1,Gik`2]| by A82,EUCLID:53;
A84: Gi1k in pio by RLTOPSP1:68;
A85: Gi1k in poz by RLTOPSP1:68;
  now per cases;
    suppose Gik`1 <> Gij`1 & Gik`2 <> Gij`2;
      then pion is being_S-Seq by A83,TOPREAL3:34;
      then consider pion1 be FinSequence of TOP-REAL 2 such that
A86:  pion1 is_sequence_on G and
A87:  pion1 is being_S-Seq and
A88:  L~pion = L~pion1 and
A89:  pion/.1 = pion1/.1 and
A90:  pion/.len pion = pion1/.len pion1 and
A91:  len pion <= len pion1 by A81,GOBOARD3:2;
      reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A87;
      set godo = go^'pion1^'co;
A92:  Gi1k`1 = G*(i1,1)`1 by A1,A6,A10,A16,GOBOARD5:2
        .= Gij`1 by A1,A4,A10,A15,GOBOARD5:2;
A93:  Gi1k`1 <= Gik`1 by A1,A2,A3,A6,A16,JORDAN1A:18;
      then
A94:  W-bound poz = Gi1k`1 by SPRECT_1:54;
A95:  W-bound pio = Gij`1 by A92,SPRECT_1:54;
      W-bound (poz \/ pio) = min(W-bound poz, W-bound pio) by SPRECT_1:47
        .= Gij`1 by A92,A94,A95;
      then
A96:  W-bound L~pion1 = Gij`1 by A88,TOPREAL3:16;
A97:  1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
A98:  1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
      len (go^'pion1) >= len go by TOPREAL8:7;
      then
A99:  len (go^'pion1) >= 1+1 by A36,XXREAL_0:2;
      then
A100: len (go^'pion1) > 1+0 by NAT_1:13;
A101: len godo >= len (go^'pion1) by TOPREAL8:7;
      then
A102: 1+1 <= len godo by A99,XXREAL_0:2;
A103: US is_sequence_on G by JORDAN1G:4;
A104: go/.len go = pion1/.1 by A44,A89,FINSEQ_4:18;
      then
A105: go^'pion1 is_sequence_on G by A38,A86,TOPREAL8:12;
A106: (go^'pion1)/.len (go^'pion1) = pion/.len pion by A90,FINSEQ_6:156
        .= pion/.3 by FINSEQ_1:45
        .= co/.1 by A45,FINSEQ_4:18;
      then
A107: godo is_sequence_on G by A41,A105,TOPREAL8:12;
      LSeg(pion1,1) c= L~pion by A88,TOPREAL3:19;
      then
A108: LSeg(go,len go-'1) /\ LSeg(pion1,1) c={Gij} by A47,A54,XBOOLE_1:27;
      len pion1 >= 2+1 by A91,FINSEQ_1:45;
      then
A109: len pion1 > 1+1 by NAT_1:13;
      {Gij} c= LSeg(go,m) /\ LSeg(pion1,1)
      proof
        let x be object;
        assume x in {Gij};
        then
A110:   x = Gij by TARSKI:def 1;
A111:   Gij in LSeg(go,m) by A51,RLTOPSP1:68;
        Gij in LSeg(pion1,1) by A44,A104,A109,TOPREAL1:21;
        hence thesis by A110,A111,XBOOLE_0:def 4;
      end;
      then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go }
      by A44,A47,A108;
      then
A112: go^'pion1 is unfolded by A104,TOPREAL8:34;
      len pion1 >= 2+1 by A91,FINSEQ_1:45;
      then
A113: len pion1-2 >= 0 by XREAL_1:19;
      len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
      then len (go^'pion1)-1 = len go + (len pion1-2)
        .= len go + (len pion1-'2) by A113,XREAL_0:def 2;
      then
A114: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A115: len pion1-1 >= 1 by A109,XREAL_1:19;
      then
A116: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A117: len pion1-'2+1 = len pion1-2+1 by A113,XREAL_0:def 2
        .= len pion1-'1 by A115,XREAL_0:def 2;
      len pion1-1+1 <= len pion1;
      then
A118: len pion1-'1 < len pion1 by A116,NAT_1:13;
      LSeg(pion1,len pion1-'1) c= L~pion by A88,TOPREAL3:19;
      then
A119: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gik} by A61,XBOOLE_1:27;
      {Gik} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
      proof
        let x be object;
        assume x in {Gik};
        then
A120:   x = Gik by TARSKI:def 1;
A121:   Gik in LSeg(co,1) by A58,RLTOPSP1:68;
        pion1/.(len pion1-'1+1) = pion/.3 by A90,A116,FINSEQ_1:45
          .= Gik by FINSEQ_4:18;
        then Gik in LSeg(pion1,len pion1-'1) by A115,A116,TOPREAL1:21;
        hence thesis by A120,A121,XBOOLE_0:def 4;
      end;
      then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gik}
      by A119;
      then
A122: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) =
      {(go^'pion1)/.len (go^'pion1)} by A45,A104,A106,A117,A118,TOPREAL8:31;
A123: (go^'pion1) is non trivial by A99,NAT_D:60;
A124: rng pion1 c= L~pion1 by A109,SPPOL_2:18;
A125: {pion1/.1} c= L~go /\ L~pion1
      proof
        let x be object;
        assume x in {pion1/.1};
        then
A126:   x = pion1/.1 by TARSKI:def 1;
        then
A127:   x in rng go by A104,FINSEQ_6:168;
        x in rng pion1 by A126,FINSEQ_6:42;
        hence thesis by A64,A124,A127,XBOOLE_0:def 4;
      end;
      L~go /\ L~pion1 c= {pion1/.1}
      proof
        let x be object;
        assume
A128:   x in L~go /\ L~pion1;
        then
A129:   x in L~go by XBOOLE_0:def 4;
        x in L~pion1 by A128,XBOOLE_0:def 4;
        hence thesis by A7,A12,A44,A49,A88,A104,A129,XBOOLE_0:def 4;
      end;
      then
A130: L~go /\ L~pion1 = {pion1/.1} by A125;
      then
A131: (go^'pion1) is s.n.c. by A104,JORDAN1J:54;
      rng go /\ rng pion1 c= {pion1/.1} by A64,A124,A130,XBOOLE_1:27;
      then
A132: go^'pion1 is one-to-one by JORDAN1J:55;
A133: pion/.len pion = pion/.3 by FINSEQ_1:45
        .= co/.1 by A45,FINSEQ_4:18;
A134: {pion1/.len pion1} c= L~co /\ L~pion1
      proof
        let x be object;
        assume x in {pion1/.len pion1};
        then
A135:   x = pion1/.len pion1 by TARSKI:def 1;
        then
A136:   x in rng co by A90,A133,FINSEQ_6:42;
        x in rng pion1 by A135,FINSEQ_6:168;
        hence thesis by A65,A124,A136,XBOOLE_0:def 4;
      end;
      L~co /\ L~pion1 c= {pion1/.len pion1}
      proof
        let x be object;
        assume
A137:   x in L~co /\ L~pion1;
        then
A138:   x in L~co by XBOOLE_0:def 4;
        x in L~pion1 by A137,XBOOLE_0:def 4;
        hence thesis by A8,A12,A45,A56,A88,A90,A133,A138,XBOOLE_0:def 4;
      end;
      then
A139: L~co /\ L~pion1 = {pion1/.len pion1} by A134;
A140: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A104,TOPREAL8:35
        .= {go/.1} \/ {co/.1} by A76,A90,A133,A139,XBOOLE_1:23
        .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
        .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
      co/.len co = (go^'pion1)/.1 by A63,FINSEQ_6:155;
      then reconsider godo as non constant standard special_circular_sequence
      by A102,A106,A107,A112,A114,A122,A123,A131,A132,A140,JORDAN8:4,5
,TOPREAL8:11,33,34;
A141: UA is_an_arc_of W-min C,E-max C by JORDAN6:def 8;
      then
A142: UA is connected by JORDAN6:10;
A143: W-min C in UA by A141,TOPREAL1:1;
A144: E-max C in UA by A141,TOPREAL1:1;
      set ff = Rotate(Cage(C,n),Wmin);
      Wmin in rng Cage(C,n) by SPRECT_2:43;
      then
A145: ff/.1 = Wmin by FINSEQ_6:92;
A146: L~ff = L~Cage(C,n) by REVROT_1:33;
      then (W-max L~ff)..ff > 1 by A145,SPRECT_5:22;
      then (N-min L~ff)..ff > 1 by A145,A146,SPRECT_5:23,XXREAL_0:2;
      then (N-max L~ff)..ff > 1 by A145,A146,SPRECT_5:24,XXREAL_0:2;
      then
A147: Emax..ff > 1 by A145,A146,SPRECT_5:25,XXREAL_0:2;
A148: now
        assume
A149:   Gij..US <= 1;
        Gij..US >= 1 by A37,FINSEQ_4:21;
        then Gij..US = 1 by A149,XXREAL_0:1;
        then Gij = US/.1 by A37,FINSEQ_5:38;
        hence contradiction by A22,A26,JORDAN1F:5;
      end;
A150: Cage(C,n) is_sequence_on G by JORDAN9:def 1;
      then
A151: ff is_sequence_on G by REVROT_1:34;
A152: right_cell(godo,1,G)\L~godo c= RightComp godo by A102,A107,JORDAN9:27;
A153: L~godo = L~(go^'pion1) \/ L~co by A106,TOPREAL8:35
        .= L~go \/ L~pion1 \/ L~co by A104,TOPREAL8:35;
A154: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
      then
A155: L~US c= L~Cage(C,n) by XBOOLE_1:7;
A156: L~LS c= L~Cage(C,n) by A154,XBOOLE_1:7;
A157: L~go c=L~Cage(C,n) by A49,A155;
A158: L~co c=L~Cage(C,n) by A56,A156;
A159: W-min C in C by SPRECT_1:13;
A160: now
        assume W-min C in L~godo;
        then
A161:   W-min C in L~go \/ L~pion1 or W-min C in L~co by A153,XBOOLE_0:def 3;
        per cases by A161,XBOOLE_0:def 3;
        suppose W-min C in L~go;
          then C meets L~Cage(C,n) by A157,A159,XBOOLE_0:3;
          hence contradiction by JORDAN10:5;
        end;
        suppose W-min C in L~pion1;
          hence contradiction by A9,A12,A88,A143,XBOOLE_0:3;
        end;
        suppose W-min C in L~co;
          then C meets L~Cage(C,n) by A158,A159,XBOOLE_0:3;
          hence contradiction by JORDAN10:5;
        end;
      end;
      right_cell(Rotate(Cage(C,n),Wmin),1) =
      right_cell(ff,1,GoB ff) by A98,JORDAN1H:23
        .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
        .= right_cell(ff,1,G) by JORDAN1H:44
        .= right_cell(ff-:Emax,1,G) by A147,A151,JORDAN1J:53
        .= right_cell(US,1,G) by JORDAN1E:def 1
        .= right_cell(R_Cut(US,Gij),1,G) by A37,A103,A148,JORDAN1J:52
        .= right_cell(go^'pion1,1,G) by A42,A105,JORDAN1J:51
        .= right_cell(godo,1,G) by A100,A107,JORDAN1J:51;
      then W-min C in right_cell(godo,1,G) by JORDAN1I:6;
      then
A162: W-min C in right_cell(godo,1,G)\L~godo by A160,XBOOLE_0:def 5;
A163: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
        .= Wmin by A62,FINSEQ_6:155;
A164: len US >= 2 by A21,XXREAL_0:2;
A165: godo/.2 = (go^'pion1)/.2 by A99,FINSEQ_6:159
        .= US/.2 by A36,A79,FINSEQ_6:159
        .= (US^'LS)/.2 by A164,FINSEQ_6:159
        .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
A166: L~go \/ L~co is compact by COMPTS_1:10;
      Wmin in L~go \/ L~co by A64,A80,XBOOLE_0:def 3;
      then
A167: W-min (L~go \/ L~co) = Wmin by A157,A158,A166,JORDAN1J:21,XBOOLE_1:8;
A169: Wmin`1 = Wbo;
      Gij`1 >= Wbo by A14,A155,PSCOMP_1:24;
      then Gij`1 > Wbo by A78,XXREAL_0:1;
      then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co)
      by A96,A166,A167,A169,JORDAN1J:33;
      then
A170: W-min L~godo = Wmin by A153,A167,XBOOLE_1:4;
A171: rng godo c= L~godo by A99,A101,SPPOL_2:18,XXREAL_0:2;
      2 in dom godo by A102,FINSEQ_3:25;
      then
A172: godo/.2 in rng godo by PARTFUN2:2;
      godo/.2 in W-most L~Cage(C,n) by A165,JORDAN1I:25;
      then (godo/.2)`1 = (W-min L~godo)`1 by A170,PSCOMP_1:31
        .= W-bound L~godo;
      then godo/.2 in W-most L~godo by A171,A172,SPRECT_2:12;
      then Rotate(godo,W-min L~godo)/.2 in W-most L~godo
      by A163,A170,FINSEQ_6:89;
      then reconsider godo as clockwise_oriented non constant standard
      special_circular_sequence by JORDAN1I:25;
      len US in dom US by FINSEQ_5:6;
      then
A173: US.len US = US/.len US by PARTFUN1:def 6
        .= Emax by JORDAN1F:7;
A174: east_halfline E-max C misses L~go
      proof
        assume east_halfline E-max C meets L~go;
        then consider p be object such that
A175:   p in east_halfline E-max C and
A176:   p in L~go by XBOOLE_0:3;
        reconsider p as Point of TOP-REAL 2 by A175;
        p in L~US by A49,A176;
        then p in east_halfline E-max C /\ L~Cage(C,n)
        by A155,A175,XBOOLE_0:def 4;
        then
   p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
        then
   p = Emax by A49,A176,JORDAN1J:46;
        then Emax = Gij by A14,A173,A176,JORDAN1J:43;
        then Gij`1 = G*(len G,k)`1 by A6,A16,A20,JORDAN1A:71;
        hence contradiction by A2,A3,A17,A33,JORDAN1G:7;
      end;
      now
        assume east_halfline E-max C meets L~godo;
        then
A179:   east_halfline E-max C meets (L~go \/ L~pion1) or
        east_halfline E-max C meets L~co by A153,XBOOLE_1:70;
        per cases by A179,XBOOLE_1:70;
        suppose east_halfline E-max C meets L~go;
          hence contradiction by A174;
        end;
        suppose east_halfline E-max C meets L~pion1;
          then consider p be object such that
A180:     p in east_halfline E-max C and
A181:     p in L~pion1 by XBOOLE_0:3;
          reconsider p as Point of TOP-REAL 2 by A180;
A182:     now per cases by A12,A88,A181,XBOOLE_0:def 3;
            suppose p in poz;
              hence p`1 <= Gik`1 by A93,TOPREAL1:3;
            end;
            suppose p in pio;
              hence p`1 <= Gik`1 by A92,A93,GOBOARD7:5;
            end;
          end;
          i2+1 <= len G by A3,NAT_1:13;
          then i2 <= len G-1 by XREAL_1:19;
          then
A183:     i2 <= len G-'1 by XREAL_0:def 2;
          len G-'1 <= len G by NAT_D:35;
          then Gik`1 <= G*(len G-'1,1)`1 by A6,A11,A16,A20,A24,A183,JORDAN1A:18
;
          then p`1 <= G*(len G-'1,1)`1 by A182,XXREAL_0:2;
          then p`1 <= E-bound C by A24,JORDAN8:12;
          then
A184:     p`1 <= (E-max C)`1;
          p`1 >= (E-max C)`1 by A180,TOPREAL1:def 11;
          then
A185:     p`1 = (E-max C)`1 by A184,XXREAL_0:1;
          p`2 = (E-max C)`2 by A180,TOPREAL1:def 11;
          then p = E-max C by A185,TOPREAL3:6;
          hence contradiction by A9,A12,A88,A144,A181,XBOOLE_0:3;
        end;
        suppose east_halfline E-max C meets L~co;
          then consider p be object such that
A186:     p in east_halfline E-max C and
A187:     p in L~co by XBOOLE_0:3;
          reconsider p as Point of TOP-REAL 2 by A186;
          p in L~LS by A56,A187;
          then p in east_halfline E-max C /\ L~Cage(C,n)
          by A156,A186,XBOOLE_0:def 4;
          then
A188:     p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A189:     (E-max C)`2 = p`2 by A186,TOPREAL1:def 11;
          set RC = Rotate(Cage(C,n),Emax);
A190:     E-max C in right_cell(RC,1) by JORDAN1I:7;
A191:     1+1 <= len LS by A28,XXREAL_0:2;
          LS = RC-:Wmin by JORDAN1G:18;
          then
A192:     LSeg(LS,1) = LSeg(RC,1) by A191,SPPOL_2:9;
A193:     L~RC = L~Cage(C,n) by REVROT_1:33;
A194:     len RC = len Cage(C,n) by FINSEQ_6:179;
A195:     GoB RC = GoB Cage(C,n) by REVROT_1:28
            .= G by JORDAN1H:44;
A196:     Emax in rng Cage(C,n) by SPRECT_2:46;
A197:     RC is_sequence_on G by A150,REVROT_1:34;
A198:     RC/.1 = E-max L~RC by A193,A196,FINSEQ_6:92;
          consider ii,jj be Nat such that
A199:     [ii,jj+1] in Indices G and
A200:     [ii,jj] in Indices G and
A201:     RC/.1 = G*(ii,jj+1) and
A202:     RC/.(1+1) = G*(ii,jj) by A97,A193,A194,A196,A197,FINSEQ_6:92
,JORDAN1I:23;
          consider jj2 be Nat such that
A203:     1 <= jj2 and
A204:     jj2 <= width G and
A205:     Emax = G*(len G,jj2) by JORDAN1D:25;
A206:     len G >= 4 by JORDAN8:10;
          then len G >= 1 by XXREAL_0:2;
          then [len G,jj2] in Indices G by A203,A204,MATRIX_0:30;
          then
A207:     ii = len G by A193,A198,A199,A201,A205,GOBOARD1:5;
A208:     1 <= ii by A199,MATRIX_0:32;
A209:     ii <= len G by A199,MATRIX_0:32;
A210:     1 <= jj+1 by A199,MATRIX_0:32;
A211:     jj+1 <= width G by A199,MATRIX_0:32;
A212:     1 <= ii by A200,MATRIX_0:32;
A213:     ii <= len G by A200,MATRIX_0:32;
A214:     1 <= jj by A200,MATRIX_0:32;
A215:     jj <= width G by A200,MATRIX_0:32;
A216:     ii+1 <> ii;
          jj+1+1 <> jj;
          then
A217:     right_cell(RC,1) = cell(G,ii-'1,jj)
          by A97,A194,A195,A199,A200,A201,A202,A216,GOBOARD5:def 6;
A218:     ii-'1+1 = ii by A208,XREAL_1:235;
          ii-1 >= 4-1 by A206,A207,XREAL_1:9;
          then
A219:     ii-1 >= 1 by XXREAL_0:2;
          then
A220:     1 <= ii-'1 by XREAL_0:def 2;
A221:     G*(ii-'1,jj)`2 <= p`2 by A189,A190,A209,A211,A214,A217,A218,A219,
JORDAN9:17;
A222:     p`2 <= G*(ii-'1,jj+1)`2 by A189,A190,A209,A211,A214,A217,A218,A219,
JORDAN9:17;
A223:     ii-'1 < len G by A209,A218,NAT_1:13;
          then
A224:     G*(ii-'1,jj)`2 = G*(1,jj)`2 by A214,A215,A220,GOBOARD5:1
            .= G*(ii,jj)`2 by A212,A213,A214,A215,GOBOARD5:1;
A225:     G*(ii-'1,jj+1)`2 = G*(1,jj+1)`2 by A210,A211,A220,A223,GOBOARD5:1
            .= G*(ii,jj+1)`2 by A208,A209,A210,A211,GOBOARD5:1;
A226:     G*(len G,jj)`1 = Ebo by A20,A214,A215,JORDAN1A:71;
          Ebo = G*(len G,jj+1)`1 by A20,A210,A211,JORDAN1A:71;
          then p in LSeg(RC/.1,RC/.(1+1))
          by A188,A201,A202,A207,A221,A222,A224,A225,A226,GOBOARD7:7;
          then
A227:     p in LSeg(LS,1) by A97,A192,A194,TOPREAL1:def 3;
A228:     p in LSeg(co,Index(p,co)) by A187,JORDAN3:9;
A229:     co = mid(LS,Gik..LS,len LS) by A40,JORDAN1J:37;
A230:     1<=Gik..LS by A40,FINSEQ_4:21;
A231:     Gik..LS<=len LS by A40,FINSEQ_4:21;
          Gik..LS <> len LS by A32,A40,FINSEQ_4:19;
          then
A232:     Gik..LS < len LS by A231,XXREAL_0:1;
A233:     1<=Index(p,co) by A187,JORDAN3:8;
A234:     Index(p,co) < len co by A187,JORDAN3:8;
A235:     Index(Gik,LS)+1 = Gik..LS by A35,A40,JORDAN1J:56;
          consider t be Nat such that
A236:     t in dom LS and
A237:     LS.t = Gik by A40,FINSEQ_2:10;
A238:     1 <= t by A236,FINSEQ_3:25;
A239:     t <= len LS by A236,FINSEQ_3:25;
          1 < t by A35,A237,A238,XXREAL_0:1;
          then Index(Gik,LS)+1 = t by A237,A239,JORDAN3:12;
          then
A240:     len L_Cut(LS,Gik) = len LS-Index(Gik,LS) by A13,A237,JORDAN3:26;
          set tt = Index(p,co)+(Gik..LS)-'1;
A241:     1<=Index(Gik,LS) by A13,JORDAN3:8;
          0+Index(Gik,LS) < len LS by A13,JORDAN3:8;
          then
A242:     len LS-Index(Gik,LS) > 0 by XREAL_1:20;
          Index(p,co) < len LS-'Index(Gik,LS) by A234,A240,XREAL_0:def 2;
          then Index(p,co)+1 <= len LS-'Index(Gik,LS) by NAT_1:13;
          then Index(p,co) <= len LS-'Index(Gik,LS)-1 by XREAL_1:19;
          then Index(p,co) <= len LS-Index(Gik,LS)-1 by A242,XREAL_0:def 2;
          then Index(p,co) <= len LS-Gik..LS by A235;
          then Index(p,co) <= len LS-'Gik..LS by XREAL_0:def 2;
          then Index(p,co) < len LS-'(Gik..LS)+1 by NAT_1:13;
          then
A243:     LSeg(mid(LS,Gik..LS,len LS),Index(p,co)) =
          LSeg(LS,Index(p,co)+(Gik..LS)-'1) by A230,A232,A233,JORDAN4:19;
A244:     1+1 <= Gik..LS by A235,A241,XREAL_1:7;
          then Index(p,co)+Gik..LS >= 1+1+1 by A233,XREAL_1:7;
          then Index(p,co)+Gik..LS-1 >= 1+1+1-1 by XREAL_1:9;
          then
A245:     tt >= 1+1 by XREAL_0:def 2;
A246:     2 in dom LS by A191,FINSEQ_3:25;
          now per cases by A245,XXREAL_0:1;
            suppose tt > 1+1;
              then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
              hence contradiction by A227,A228,A229,A243,XBOOLE_0:3;
            end;
            suppose
A247:         tt = 1+1;
              then LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A28,TOPREAL1:def 6;
              then p in {LS/.2} by A227,A228,A229,A243,XBOOLE_0:def 4;
              then
A248:         p = LS/.2 by TARSKI:def 1;
              then
A249:         p..LS = 2 by A246,FINSEQ_5:41;
              1+1 = Index(p,co)+(Gik..LS)-1 by A247,XREAL_0:def 2;
              then 1+1+1 = Index(p,co)+(Gik..LS);
              then
A250:         Gik..LS = 2 by A233,A244,JORDAN1E:6;
              p in rng LS by A246,A248,PARTFUN2:2;
              then p = Gik by A40,A249,A250,FINSEQ_5:9;
              then Gik`1 = Ebo by A248,JORDAN1G:32;
              then Gik`1 = G*(len G,j)`1 by A4,A15,A20,JORDAN1A:71;
              hence contradiction by A3,A18,A70,JORDAN1G:7;
            end;
          end;
          hence contradiction;
        end;
      end;
      then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
      then consider W be Subset of TOP-REAL 2 such that
A251: W is_a_component_of (L~godo)` and
A252: east_halfline E-max C c= W by GOBOARD9:3;
      W is not bounded by A252,JORDAN2C:121,RLTOPSP1:42;
      then W is_outside_component_of L~godo by A251,JORDAN2C:def 3;
      then W c= UBD L~godo by JORDAN2C:23;
      then
A253: east_halfline E-max C c= UBD L~godo by A252;
      E-max C in east_halfline E-max C by TOPREAL1:38;
      then E-max C in UBD L~godo by A253;
      then E-max C in LeftComp godo by GOBRD14:36;
      then UA meets L~godo by A142,A143,A144,A152,A162,JORDAN1J:36;
      then
A254: UA meets (L~go \/ L~pion1) or UA meets L~co by A153,XBOOLE_1:70;
A255: UA c= C by JORDAN6:61;
      now per cases by A254,XBOOLE_1:70;
        suppose UA meets L~go;
          then UA meets L~Cage(C,n) by A49,A155,XBOOLE_1:1,63;
          hence contradiction by A255,JORDAN10:5,XBOOLE_1:63;
        end;
        suppose UA meets L~pion1;
          hence contradiction by A9,A12,A88;
        end;
        suppose UA meets L~co;
          then UA meets L~Cage(C,n) by A56,A156,XBOOLE_1:1,63;
          hence contradiction by A255,JORDAN10:5,XBOOLE_1:63;
        end;
      end;
      hence contradiction;
    end;
    suppose Gik`1 = Gij`1;
      then
A256: i1 = i2 by A17,A18,JORDAN1G:7;
      then poz = {Gi1k} by RLTOPSP1:70;
      then poz c= pio by A84,ZFMISC_1:31;
      then pio \/ poz = pio by XBOOLE_1:12;
      hence contradiction by A1,A3,A4,A5,A6,A7,A8,A9,A256,Th12;
    end;
    suppose Gik`2 = Gij`2;
      then
A257: j = k by A17,A18,JORDAN1G:6;
      then pio = {Gi1k} by RLTOPSP1:70;
      then pio c= poz by A85,ZFMISC_1:31;
      then pio \/ poz = poz by XBOOLE_1:12;
      hence contradiction by A1,A2,A3,A4,A6,A7,A8,A9,A257,JORDAN15:37;
    end;
  end;
  hence contradiction;
end;
