reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th20:
  0 < n implies ex i being Nat st 1 <= i & i <= len
  Gauge(C,n) & LMP L~Cage(C,n) = Gauge(C,n)*(Center Gauge(C,n),i)
proof
  set f = Cage(C,n), G = Gauge(C,n), w = Center G;
A1: f is_sequence_on G by JORDAN9:def 1;
A2: len G = width G by JORDAN8:def 1;
  LSeg(G*(w,1),G*(w,len G)) meets Upper_Arc L~f by JORDAN1B:31;
  then
A3: LSeg(G*(w,1),G*(w,len G)) meets L~f by JORDAN6:61,XBOOLE_1:63;
A4: w <= len G by JORDAN1B:13;
  assume
A5: 0 < n;
  then
  LMP L~f = |[ (E-bound L~f + W-bound L~f) / 2,
   lower_bound (proj2.:(L~f /\ LSeg(G
  *(w,1),G*(w,len G)))) ]| by Th14;
  then
A6: (LMP L~f)`2 = lower_bound (proj2.:(L~f /\ LSeg(G*(w,1),G*(w,len G))))
 by EUCLID:52;
A7: 1 <= len G by Lm3;
A8: 1 <= w by JORDAN1B:11;
  then
A9: [w,len G] in Indices G by A2,A7,A4,MATRIX_0:30;
  [w,1] in Indices G by A2,A7,A8,A4,MATRIX_0:30;
  then consider i such that
A10: 1 <= i and
A11: i <= len G and
A12: G*(w,i)`2 = lower_bound(proj2.:(LSeg(G*(w,1),G*(w,len G)) /\ L~f))
 by A1,A3,A7,A9,JORDAN1F:1;
A13: (LMP L~f)`1 = (E-bound L~f + W-bound L~f) / 2 by EUCLID:52;
  take i;
  thus 1 <= i & i <= len G by A10,A11;
  G*(w,i)`1 = (W-bound C + E-bound C) / 2 by A5,A2,A10,A11,JORDAN1G:35;
  then (LMP L~f)`1 = G*(w,i)`1 by A13,JORDAN1G:33;
  hence thesis by A12,A6,TOPREAL3:6;
end;
