reserve r1,r2 for Real;
reserve n,i,i1,i2,j for Nat;
reserve D for non empty set;
reserve f for FinSequence of D;

theorem Th20:
  for f being FinSequence of TOP-REAL 2, p being Point of TOP-REAL
  2 st f is being_S-Seq & p in L~f & p = f.(Index(p,f)+1) & p <> f.len f holds
  Index(p,Rev f) + Index(p,f) + 1 = len f
proof
  let f be FinSequence of TOP-REAL 2, p be Point of TOP-REAL 2 such that
A1: f is being_S-Seq and
A2: p in L~f and
A3: p = f.(Index(p,f)+1) and
A4: p <> f.len f;
A5: len f <= len f + Index(p,f) by NAT_1:11;
  len f = len Rev f by FINSEQ_5:def 3;
  then
A6: len f - Index(p,f) <= len Rev f by A5,XREAL_1:20;
  Index(p,f) <= len f by A2,Th8;
  then
A7: len f - Index(p,f) = len f -' Index(p,f) by XREAL_1:233;
  Index(p,f) < len f by A2,Th8;
  then
A8: Index(p,f)+1 <= len f by NAT_1:13;
  then Index(p,f)+1 < len f by A3,A4,XXREAL_0:1;
  then
A9: 1 < len f - Index(p,f) by XREAL_1:20;
  1 <= Index(p,f)+1 by NAT_1:11;
  then Index(p,f)+1 in dom f by A8,FINSEQ_3:25;
  then
A10: Index(p,f)+1 in dom Rev f by FINSEQ_5:57;
  p = (Rev Rev f).(Index(p,f)+1) by A3
    .= (Rev f).(len Rev f - (Index(p,f)+1) + 1) by A10,FINSEQ_5:58
    .= (Rev f).(len Rev f - Index(p,f))
    .= (Rev f).(len f - Index(p,f)) by FINSEQ_5:def 3;
  then Index(p,Rev f) + 1 = len f -' Index(p,f) by A1,A6,A9,A7,Th12;
  hence thesis by A7;
end;
