reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th20:
  0.V1|-- b1 = len b1 |-> 0.K
proof
  per cases;
  suppose
A1: dom b1={};
    then
A2: len b1=0 by CARD_1:27,RELAT_1:41;
    len (0.V1|--b1)=len b1 by MATRLIN:def 7;
    hence 0.V1|-- b1 = {} by A1,CARD_1:27,RELAT_1:41
      .= len b1 |-> 0.K by A2;
  end;
  suppose
    dom b1<>{};
    then consider x being object such that
A3: x in dom b1 by XBOOLE_0:def 1;
A4: width 1.(K,len b1)=len b1 by MATRIX_0:24;
    reconsider x as Nat by A3;
    0.V1 = b1/.x-b1/.x by VECTSP_1:16
      .= b1/.x+(-1_K)*(b1/.x) by VECTSP_1:14;
    hence 0.V1|-- b1 = (b1/.x |-- b1) + ((-1_K)*(b1/.x) |--b1) by Th17
      .= (b1/.x |-- b1) + (-1_K)*((b1/.x) |--b1) by Th18
      .= Line(1.(K,len b1),x)+(-1_K)*((b1/.x) |--b1) by A3,Th19
      .= Line(1.(K,len b1),x)+(-1_K)*Line(1.(K,len b1),x) by A3,Th19
      .= Line(1.(K,len b1),x)+-Line(1.(K,len b1),x) by FVSUM_1:59
      .= len b1|->0.K by A4,FVSUM_1:26;
  end;
end;
