reserve X for non empty set,
  F for with_the_same_dom Functional_Sequence of X, ExtREAL,
  seq,seq1,seq2 for ExtREAL_sequence,
  x for Element of X,
  a,r for R_eal,
  n,m,k for Nat;
reserve S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S;
reserve F1,F2 for Functional_Sequence of X,ExtREAL,
  f,g,P for PartFunc of X, ExtREAL;

theorem Th20:
  F1 is_uniformly_convergent_to f implies for x be Element of X st
  x in dom(F1.0) holds F1#x is convergent & lim(F1#x) = f.x
proof
  assume
A1: F1 is_uniformly_convergent_to f;
  let x be Element of X;
  assume
A2: x in dom(F1.0);
  per cases by XXREAL_0:14;
  suppose
    f.x in REAL;
    then reconsider g=f.x as Real;
A3: now
      let e be Real;
      assume 0 < e;
      then consider N be Nat such that
A4:   for n be Nat, x be set st n >= N & x in dom(F1.0) holds |. (F1.n
      ).x - f.x .| < e by A1;
      take N;
      hereby
        let m be Nat;
        assume N <= m;
        then |. (F1.m).x - f.x .| < e by A2,A4;
        hence |. (F1#x).m - g .| < e by MESFUNC5:def 13;
      end;
    end;
    then
A5: F1#x is convergent_to_finite_number;
    then F1#x is convergent;
    hence thesis by A3,A5,MESFUNC5:def 12;
  end;
  suppose
A6: f.x = +infty;
    now
      let e be Real;
      assume 0 < e;
      then consider N be Nat such that
A7:   for n be Nat, x be set st n >= N & x in dom(F1.0) holds |. (F1.
      n).x - f.x .| < e by A1;
      take N;
      hereby
        let n be Nat;
        assume n >= N;
        then |. (F1.n).x - f.x .| < e by A2,A7;
        then
A8:     |. -( (F1.n).x - f.x ) .| < e by EXTREAL1:29;
        (F1.n).x = (F1#x).n by MESFUNC5:def 13;
        then -( (F1#x).n - f.x ) < e by A8,EXTREAL1:21;
        then f.x - (F1#x).n < e by XXREAL_3:26;
        then (F1#x).n = +infty by A6,XXREAL_3:54;
        hence e <= (F1#x).n by XXREAL_0:3;
      end;
    end;
    then
A9: F1#x is convergent_to_+infty;
    then F1#x is convergent;
    hence thesis by A6,A9,MESFUNC5:def 12;
  end;
  suppose
A10: f.x = -infty;
    now
      let e be Real;
      assume e < 0;
      then -0 < -e by XREAL_1:24;
      then consider N be Nat such that
A11:  for n be Nat, x be set st n >= N & x in dom(F1.0) holds |. (F1.
      n).x - f.x .| < -e by A1;
      take N;
      hereby
        let n be Nat;
        assume n >= N;
        then
A12:    |. (F1.n).x - f.x .| < -e by A2,A11;
        (F1.n).x = (F1#x).n by MESFUNC5:def 13;
        then (F1#x).n - f.x < -e by A12,EXTREAL1:21;
        then (F1#x).n = -infty by A10,XXREAL_3:54;
        hence e >= (F1#x).n by XXREAL_0:5;
      end;
    end;
    then
A13: F1#x is convergent_to_-infty;
    then F1#x is convergent;
    hence thesis by A10,A13,MESFUNC5:def 12;
  end;
end;
