reserve T, T1 for non empty TopSpace;
reserve F,G,H for Subset-Family of T,
  A,B,C,D for Subset of T,
  O,U for open Subset of T,
  p,q for Point of T,
  x,y,X for set;
reserve Un for FamilySequence of T,
  r,r1,r2 for Real,
  n for Element of NAT;

theorem
  for T st T is regular & ex Bn being FamilySequence of T st Bn is
  Basis_sigma_locally_finite holds T is normal
proof
  let T;
  assume that
A1: T is regular and
A2: ex Bn being FamilySequence of T st Bn is Basis_sigma_locally_finite;
  consider Bn being FamilySequence of T such that
A3: Bn is Basis_sigma_locally_finite by A2;
A4: Union Bn is Basis of T by A3;
A5: Bn is sigma_locally_finite by A3;
  for A,U st A is closed & U is open & A c=U ex W being sequence of
bool(the carrier of T) st A c= Union W & Union W c= U & for n holds Cl (W.n) c=
  U & W.n is open
  proof
    let A,U;
    assume that
    A is closed and
    U is open and
A6: A c=U;
    deffunc B(object)=union{O where O is Subset of T: O in Bn.$1 & Cl O c=U};
A7: for k being object st k in NAT holds B(k) in bool the carrier of T
    proof
      let k be object;
      assume k in NAT;
      then reconsider k as Element of NAT;
      now
        let bu be object;
        assume bu in B(k);
        then consider b being set such that
A8:     bu in b and
A9:     b in {O where O is Subset of T: O in Bn.k & Cl O c=U} by TARSKI:def 4;
        ex O being Subset of T st b=O & O in Bn.k & Cl O c=U by A9;
        hence bu in the carrier of T by A8;
      end;
      then B(k) c= the carrier of T;
      hence thesis;
    end;
    consider BU being sequence of  bool (the carrier of T) such that
A10: for k being object st k in NAT holds BU.k= B(k) from FUNCT_2:sch 2(
    A7);
A11: now
      let n;
      set BUn={O where O is Subset of T: O in Bn.n & Cl O c=U};
      BUn c= bool the carrier of T
      proof
        let b be object;
        assume b in BUn;
        then ex O being Subset of T st b=O & O in Bn.n & Cl O c=U;
        hence thesis;
      end;
      then reconsider BUn as Subset-Family of T;
A12:  BUn c=Bn.n
      proof
        let b be object;
        assume b in BUn;
        then ex O being Subset of T st b=O & O in Bn.n & Cl O c=U;
        hence thesis;
      end;
      Bn.n is locally_finite by A5;
      then
A13:  Cl union(BUn)= union(clf BUn) by A12,PCOMPS_1:9,20;
A14:  Cl union(BUn)c=U
      proof
        let ClBu be object;
        assume ClBu in Cl union(BUn);
        then consider ClB being set such that
A15:    ClBu in ClB and
A16:    ClB in clf BUn by A13,TARSKI:def 4;
        reconsider ClB as Subset of T by A16;
        consider B being Subset of T such that
A17:    Cl B =ClB and
A18:    B in BUn by A16,PCOMPS_1:def 2;
        ex Q being Subset of T st B=Q & Q in Bn.n & Cl Q c=U by A18;
        hence thesis by A15,A17;
      end;
      BUn c= the topology of T
      proof
        let B be object;
        assume B in BUn;
        then consider Q being Subset of T such that
A19:    B=Q and
A20:    Q in Bn.n and
        Cl Q c=U;
A21:    Union Bn c= the topology of T by A4,TOPS_2:64;
        Q in Union Bn by A20,PROB_1:12;
        hence thesis by A19,A21;
      end;
      then union BUn in the topology of T by PRE_TOPC:def 1;
      then union BUn is open by PRE_TOPC:def 2;
      hence BU.n is open & Cl (BU.n) c=U by A10,A14;
    end;
A22: Union BU c= U
    proof
      let bu be object;
      assume bu in Union BU;
      then consider k being Nat such that
A23:  bu in BU.k by PROB_1:12;
A24:  k in NAT by ORDINAL1:def 12;
      bu in union {O where O is Subset of T: O in Bn.k & Cl O c=U}
             by A10,A23,A24;
      then consider b being set such that
A25:  bu in b and
A26:  b in {O where O is Subset of T: O in Bn.k & Cl O c=U} by TARSKI:def 4;
      consider O being Subset of T such that
A27:  b=O and
      O in Bn.k and
A28:  Cl O c=U by A26;
      O c= Cl O by PRE_TOPC:18;
      then b c= U by A27,A28;
      hence thesis by A25;
    end;
    for a being object st a in A holds a in Union BU
    proof
      let a be object;
      assume a in A;
      then consider Q being Subset of T such that
A29:  a in Q and
A30:  Cl Q c= U and
A31:  Q in Union Bn by A1,A4,A6,Th19;
      consider k being Nat such that
A32:  Q in Bn.k by A31,PROB_1:12;
A33:  k in NAT by ORDINAL1:def 12;
      Q in {O where O is Subset of T: O in Bn.k & Cl O c=U} by A30,A32;
      then a in B(k) by A29,TARSKI:def 4;
      then a in BU.k by A10,A33;
      hence thesis by PROB_1:12;
    end;
    then A c= Union BU;
    hence thesis by A22,A11;
  end;
  hence thesis by Th18;
end;
