reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th20:
  for G being non empty irreflexive RelStr, x being Element of G,
x9 being Element of ComplRelStr G st x = x9 holds ComplRelStr (subrelstr ([#]G
  \ {x})) = subrelstr ([#](ComplRelStr G) \ {x9})
proof
  let G be non empty irreflexive RelStr, x be Element of G, x9 be Element of
  ComplRelStr G;
  assume
A1: x = x9;
  set R = subrelstr ([#]G \ {x}), cR = the carrier of R, cG = the carrier of G;
A2: [#]ComplRelStr G = cG by NECKLACE:def 8;
A3: [:(cG \ {x}),(cG \ {x}):] = [:cR,([#]G \ {x}):] by YELLOW_0:def 15
    .= [:cR,cR:] by YELLOW_0:def 15;
A4: cR c= cG by YELLOW_0:def 13;
A5: the InternalRel of subrelstr ([#](ComplRelStr G) \ {x9}) = (the
InternalRel of ComplRelStr G)|_2 the carrier of subrelstr ([#](ComplRelStr G) \
  {x9}) by YELLOW_0:def 14
    .= (the InternalRel of ComplRelStr G)|_2 (cG \ {x}) by A1,A2,
YELLOW_0:def 15
    .= ((the InternalRel of G)` \ id cG ) /\ [:(cG \ {x}),(cG \ {x}):] by
NECKLACE:def 8
    .= ( [:cR,cR:] /\ (the InternalRel of G)` ) \ id cG by A3,XBOOLE_1:49
    .= ( [:cR,cR:] /\ ([:cG,cG:] \ the InternalRel of G) ) \ id cG by
SUBSET_1:def 4
    .= ( ([:cR,cR:] /\ [:cG,cG:]) \ the InternalRel of G) \ id cG by
XBOOLE_1:49
    .= ([:cR,cR:] \ (the InternalRel of G)) \ id cG by A4,XBOOLE_1:28
,ZFMISC_1:96;
A6: the InternalRel of ComplRelStr R = (the InternalRel of R)` \ id cR by
NECKLACE:def 8
    .= [:cR,cR:] \ (the InternalRel of R) \ id cR by SUBSET_1:def 4
    .= [:cR,cR:] \ ( (the InternalRel of G)|_2 cR ) \id cR by YELLOW_0:def 14
    .= ( ([:cR,cR:] \ (the InternalRel of G)) \/ ([:cR,cR:] \ [:cR,cR:]) ) \
  id cR by XBOOLE_1:54
    .= ( ([:cR,cR:] \ (the InternalRel of G)) \/ {}) \ id cR by XBOOLE_1:37
    .= ([:cR,cR:] \ (the InternalRel of G)) \ id cR;
A7: [:cR,cR:] = [:[#]G,([#]G \ {x}):] \ [:{x},([#]G \ {x}):] by A3,ZFMISC_1:102
    .= [:[#]G,[#]G:] \ [:[#]G,{x}:] \ [:{x},([#]G\{x}):] by ZFMISC_1:102
    .= [:cG,cG:] \ [:cG,{x}:] \ ([:{x},cG:] \ [:{x},{x}:]) by ZFMISC_1:102
    .= ( ([:cG,cG:] \ [:cG,{x}:]) \ [:{x},cG:] ) \/ ([:cG,cG:] \ [:cG,{x}:])
  /\ [:{x},{x}:] by XBOOLE_1:52
    .= ([:cG,cG:] \ ([:cG,{x}:] \/ [:{x},cG:]) ) \/ ([:cG,cG:] \ [:cG,{x}:])
  /\ [:{x},{x}:] by XBOOLE_1:41;
A8: the InternalRel of subrelstr ([#](ComplRelStr G) \ {x9}) = the
  InternalRel of ComplRelStr R
  proof
    thus the InternalRel of subrelstr ([#](ComplRelStr G) \ {x9}) c= the
    InternalRel of ComplRelStr R
    proof
      let a be object;
      assume
A9:   a in the InternalRel of subrelstr ([#](ComplRelStr G) \ {x9});
      then
A10:  not a in id cG by A5,XBOOLE_0:def 5;
A11:  not a in id cR
      proof
        assume
A12:    not thesis;
        then consider x2,y2 being object such that
A13:    a = [x2,y2] and
A14:    x2 in cR and
        y2 in cR by RELSET_1:2;
A15:    x2 in cG \ {x} by A14,YELLOW_0:def 15;
        x2 = y2 by A12,A13,RELAT_1:def 10;
        hence contradiction by A10,A13,A15,RELAT_1:def 10;
      end;
      a in ([:cR,cR:] \ (the InternalRel of G)) by A5,A9,XBOOLE_0:def 5;
      hence thesis by A6,A11,XBOOLE_0:def 5;
    end;
    let a be object;
    assume
A16: a in the InternalRel of ComplRelStr R;
    then not a in id cR by A6,XBOOLE_0:def 5;
    then not a in id (cG \ {x}) by YELLOW_0:def 15;
    then
A17: not a in (id cG \ id {x}) by SYSREL:14;
    per cases by A17,XBOOLE_0:def 5;
    suppose
A18:  not a in id cG;
      a in ([:cR,cR:] \ (the InternalRel of G)) by A6,A16,XBOOLE_0:def 5;
      hence thesis by A5,A18,XBOOLE_0:def 5;
    end;
    suppose
      a in id {x};
      then
A19:  a in {[x,x]} by SYSREL:13;
      thus thesis
      proof
        per cases by A7,A6,A16,XBOOLE_0:def 3;
        suppose
A20:      a in [:cG,cG:] \ ([:cG,{x}:] \/ [:{x},cG:]);
          x in {x} by TARSKI:def 1;
          then
A21:      [x,x] in [:{x},cG:] by ZFMISC_1:87;
          not a in ([:cG,{x}:] \/ [:{x},cG:]) by A20,XBOOLE_0:def 5;
          then not a in [:{x}, cG:] by XBOOLE_0:def 3;
          hence thesis by A19,A21,TARSKI:def 1;
        end;
        suppose
A22:      a in ([:cG,cG:] \ [:cG,{x}:]) /\ [:{x},{x}:];
          x in {x} by TARSKI:def 1;
          then
A23:      [x,x] in [:cG,{x}:] by ZFMISC_1:87;
          a in [:cG,cG:] \ [:cG,{x}:] by A22,XBOOLE_0:def 4;
          then not a in [:cG,{x}:] by XBOOLE_0:def 5;
          hence thesis by A19,A23,TARSKI:def 1;
        end;
      end;
    end;
  end;
  the carrier of ComplRelStr (subrelstr ([#]G \ {x})) = the carrier of (
  subrelstr ([#]G \ {x})) by NECKLACE:def 8
    .= (the carrier of G) \ {x} by YELLOW_0:def 15
    .= [#](ComplRelStr G) \ {x9} by A1,NECKLACE:def 8
    .= the carrier of subrelstr ([#](ComplRelStr G) \ {x9}) by YELLOW_0:def 15;
  hence thesis by A8;
end;
