
theorem Th33:
  for A, B being non empty Cantor-normal-form Ordinal-Sequence
  st omega -exponent(B.0) in omega -exponent last A
  holds A^B is Cantor-normal-form
proof
  let A, B be non empty Cantor-normal-form Ordinal-Sequence;
  assume A1: omega -exponent(B.0) in omega -exponent last A;
  A2: now
    let a be Ordinal;
    assume a in dom(A^B);
    then per cases by AFINSQ_1:20;
    suppose A3: a in dom A;
      then A.a = (A^B).a by AFINSQ_1:def 3;
      hence (A^B).a is Cantor-component by A3, ORDINAL5:def 11;
    end;
    suppose ex n being Nat st n in dom B & a = len A + n;
      then consider n being Nat such that
        A4: n in dom B & a = len A + n;
      B.n = (A^B).a by A4, AFINSQ_1:def 3;
      hence (A^B).a is Cantor-component by A4, ORDINAL5:def 11;
    end;
  end;
  for a,b being Ordinal st a in b & b in dom(A^B)
    holds omega -exponent((A^B).b) in omega-exponent((A^B).a)
  proof
    let a,b be Ordinal;
    assume A5: a in b & b in dom(A^B);
    then per cases by AFINSQ_1:20;
    suppose A6: b in dom A;
      then A7: (A^B).b = A.b & a in dom A by A5, ORDINAL1:10, AFINSQ_1:def 3;
      then (A^B).a = A.a by AFINSQ_1:def 3;
      hence thesis by A5, A6, A7, ORDINAL5:def 11;
    end;
    suppose ex n being Nat st n in dom B & b = len A + n;
      then consider n being Nat such that
        A8: n in dom B & b = len A + n;
      a in dom(A^B) by A5, ORDINAL1:10;
      then per cases by AFINSQ_1:20;
      suppose A9: a in dom A;
        then omega -exponent last A c= omega -exponent(A.a) by Th31;
        then A10: omega -exponent(B.0) in omega -exponent(A.a) by A1;
        omega -exponent(B.n) c= omega -exponent(B.0) by A8, Th32;
        then omega -exponent(B.n) in omega -exponent(A.a) by A10, ORDINAL1:12;
        then omega -exponent((A^B).b) in omega -exponent(A.a)
          by A8, AFINSQ_1:def 3;
        hence thesis by A9, AFINSQ_1:def 3;
      end;
      suppose ex m being Nat st m in dom B & a = len A + m;
        then consider m being Nat such that
          A11: m in dom B & a = len A + m;
        m in n
        proof
          assume not m in n;
          then len A +^ n c= len A +^ m by ORDINAL1:16, ORDINAL2:33;
          then b c= len A +^ m by A8, CARD_2:36;
          then b c= a by A11, CARD_2:36;
          then a in a by A5;
          hence contradiction;
        end;
        then omega -exponent(B.n) in omega -exponent(B.m)
          by A8, ORDINAL5:def 11;
        then omega -exponent((A^B).b) in omega -exponent(B.m)
          by A8, AFINSQ_1:def 3;
        hence thesis by A11, AFINSQ_1:def 3;
      end;
    end;
  end;
  hence thesis by A2, ORDINAL5:def 11;
end;
