
theorem
  for m be Nat st m >= 1 holds for n,k be Nat, r be Tuple of m+2,k-SD st
k >= 2 & n in Seg (m+2) & Mmask(r) is_Zero_over n & DigA(Mmask(r),n) > 0 holds
  SDDec(Mmask(r)) > 0
proof
  let m be Nat;
  assume m >= 1;
  then
A1: m+2 >= 1 by Lm1;
  let n,k be Nat, r be Tuple of m+2,k-SD;
  assume that
A2: k >= 2 and
A3: n in Seg (m+2) and
A4: Mmask(r) is_Zero_over n and
A5: DigA(Mmask(r),n)> 0;
  for i be Nat st i in Seg (m+2) holds DigA(Mmask(r),i) >= DigA(FSDMin(m+2
  ,n,k),i)
  proof
    let i be Nat;
    assume
A6: i in Seg (m+2);
    now
      per cases;
      suppose
A7:     i > n;
        DigA(FSDMin(m+2,n,k),i) = FSDMinDigit(n,k,i) by A6,Def11
          .= 0 by A2,A7,Def10;
        hence thesis by A4,A7;
      end;
      suppose
A8:     i <= n;
        now
          per cases by A8,XXREAL_0:1;
          suppose
A9:         i = n;
            then
A10:        DigA(Mmask(r),i) >= 0 + 1 by A5,INT_1:7;
            DigA(FSDMin(m+2,n,k),i) = FSDMinDigit(n,k,i) by A6,Def11
              .= 1 by A2,A9,Def10;
            hence thesis by A10;
          end;
          suppose
A11:        i < n;
A12:        DigA(Mmask(r),i) = Mmask(r).i by A6,RADIX_1:def 3;
A13:        Mmask(r).i is Element of k-SD by A6,RADIX_1:15;
            DigA(FSDMin(m+2,n,k),i) = FSDMinDigit(n,k,i) by A6,Def11
              .= -Radix(k) + 1 by A2,A11,Def10;
            hence thesis by A12,A13,RADIX_1:13;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  then SDDec(Mmask(r)) >= SDDec(FSDMin(m+2,n,k)) by A1,RADIX_5:13;
  hence thesis by A2,A3,A1,Th19;
end;
