reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;
reserve F for random_variable of S1,S2;

theorem Th20:
  for D be finite-yielding non-empty ManySortedSet of NAT,
  P be Probability_sequence of Trivial-SigmaField_sequence(D),
  n be Nat holds
  Product-Probability(P,D).n is
  Probability of Trivial-SigmaField ((Product_dom(D)).n)
  proof
    let D be finite-yielding non-empty ManySortedSet of NAT,
    P be Probability_sequence of Trivial-SigmaField_sequence(D);
    defpred Q[Nat] means Product-Probability(P,D).$1 is
    Probability of Trivial-SigmaField ((Product_dom(D)).$1);
    A1: Product-Probability(P,D).0 = P.0 by Def13;
    D.0 = (Product_dom(D)).0 by Def10; then
    A2: Q[0] by A1;
    A3: for k be Nat st Q[k] holds Q[ k + 1 ]
    proof
      let k be Nat;
      assume Q[k];
      A4: Product-Probability(P,D).(k+1) = Product-Probability
      ( (Product_dom(D)).k,D.(k+1),
      modetrans(Product-Probability(P,D).k,
      Trivial-SigmaField ((Product_dom(D)).k)), P.(k+1)) by Def13;
      (Product_dom(D)).(k+1) = [:(Product_dom(D)).k,D.(k+1):] by Def10;
      hence thesis by A4;
    end;
    for n be Nat holds Q[n] from NAT_1:sch 2(A2,A3);
    hence thesis;
  end;
