reserve i,j,k,n,m for Nat;
reserve p,q for Point of TOP-REAL 2;
reserve G for Go-board;
reserve C for Subset of TOP-REAL 2;

theorem
  for f being FinSequence of TOP-REAL 2 st 1 <= i holds i < j & j <= len
  f implies L~mid(f,i,j) = L~mid(f,i,j -' 1) \/ LSeg(f,j -' 1)
proof
  let f be FinSequence of TOP-REAL 2 such that
A1: 1 <= i and
A2: i < j and
A3: j <= len f;
  j -' 1 <= j by NAT_D:35;
  then
A4: j -' 1 <= len f by A3,XXREAL_0:2;
  set A = { LSeg(f,k): i <= k & k < j}, B = { LSeg(f,k): i <= k & k < j -' 1};
A5: i <= j -' 1 by A2,NAT_D:49;
A6: A = B \/ {LSeg(f,j -' 1)}
  proof
    thus A c= B \/ {LSeg(f,j -' 1)}
    proof
      let e be object;
      assume e in A;
      then consider k such that
A7:   e = LSeg(f,k) and
A8:   i <= k and
A9:   k < j;
      k <= j -' 1 by A9,NAT_D:49;
      then j -' 1 = k or k < j -' 1 by XXREAL_0:1;
      then e in B or e in {LSeg(f,j -' 1)} by A7,A8,TARSKI:def 1;
      hence thesis by XBOOLE_0:def 3;
    end;
    let e be object;
A10: j -' 1 <= j by NAT_D:35;
    assume
A11: e in B \/ {LSeg(f,j -' 1)};
    per cases by A11,XBOOLE_0:def 3;
    suppose
      e in B;
      then consider k such that
A12:  e = LSeg(f,k) and
A13:  i <= k and
A14:  k < j -' 1;
      k < j by A10,A14,XXREAL_0:2;
      hence thesis by A12,A13;
    end;
    suppose
A15:  e in {LSeg(f,j -' 1)};
      1 <= j -' 1 by A1,A5,XXREAL_0:2;
      then
A16:  j-' 1 < j by NAT_D:51;
      e = LSeg(f,j -' 1) by A15,TARSKI:def 1;
      hence thesis by A5,A16;
    end;
  end;
  thus L~mid(f,i,j) = union A by A1,A2,A3,SPRECT_2:14
    .= union B \/ union{LSeg(f,j -' 1)} by A6,ZFMISC_1:78
    .= union B \/ LSeg(f,j -' 1) by ZFMISC_1:25
    .= L~mid(f,i,j -' 1) \/ LSeg(f,j -' 1) by A1,A5,A4,SPRECT_2:14;
end;
