reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem
  for P being Subset of T holds P = {x} implies diameter P = 0
proof
  let P be Subset of T;
  assume
A1: P = {x};
  then
A2: x in P by TARSKI:def 1;
  then reconsider t1 = x as Element of T;
  (for x,y being Point of T st x in P & y in P holds dist(x,y)<=0) & for s
st (for x,y being Point of T st x in P & y in P holds dist(x,y)<=s) holds 0<=s
  proof
    thus for x,y being Point of T st x in P & y in P holds dist(x,y)<=0
    proof
      let x,y be Point of T such that
A3:   x in P and
A4:   y in P;
      x = t1 by A1,A3,TARSKI:def 1;
      then dist(x,y) = dist(t1,t1) by A1,A4,TARSKI:def 1
        .= 0 by METRIC_1:1;
      hence thesis;
    end;
    let s;
    assume for x,y being Point of T st x in P & y in P holds dist(x,y)<=s;
    then dist(t1,t1)<=s by A2;
    hence thesis by METRIC_1:1;
  end;
  hence thesis by A1,Def8;
end;
