
theorem Th20:
  for T being injective T_0-TopSpace holds Omega T is complete
  continuous LATTICE
proof
  let T be injective T_0-TopSpace;
  set S = Sierpinski_Space, B = BoolePoset{0};
  consider M being non empty set such that
A1: T is_Retract_of product (M --> S) by WAYBEL18:19;
  consider f being Function of product(M --> S), product(M --> S) such that
A2: f is continuous and
A3: f*f = f and
A4: Image f, T are_homeomorphic by A1;
A5: the RelStr of Omega Image f, Omega Image f are_isomorphic by WAYBEL13:26;
  Omega Image f, Omega T are_isomorphic by A4,Th19;
  then
A6: the RelStr of Omega Image f, Omega T are_isomorphic by A5,WAYBEL_1:7;
  Omega Image f is full SubRelStr of Omega product (M --> S) by Th17;
  then
A7: the InternalRel of Omega Image f = (the InternalRel of (Omega product (
  M --> S)))|_2 the carrier of Omega Image f by YELLOW_0:def 14;
  set TL = the Scott TopAugmentation of product(M --> B);
A8: the RelStr of TL = the RelStr of product(M --> B) by YELLOW_9:def 4;
A9: the carrier of TL = the carrier of product(M --> S) by Th3;
  then reconsider ff = f as Function of TL, TL;
A10: the topology of TL = the topology of product (M --> S) by WAYBEL18:15;
  then
A11: ff is continuous by A2,A9,YELLOW12:36;
  then ff is idempotent monotone by A3,QUANTAL1:def 9;
  then ff is projection;
  then reconsider
  g = ff as projection Function of product (M --> B), product (M
  --> B) by A8,Lm3;
A12: the InternalRel of Image g = (the InternalRel of (product (M --> B)))
  |_2 the carrier of Image g by YELLOW_0:def 14;
  the TopStruct of the TopStruct of TL = the TopStruct of TL implies Omega
  the TopStruct of TL = Omega TL by Th13;
  then
A13: the RelStr of Omega the TopStruct of product(M --> S) = the RelStr of
  product (M --> B) by A10,A9,Th16;
  g is directed-sups-preserving by A8,A11,WAYBEL21:6;
  then
A14: Image g is complete continuous LATTICE by WAYBEL15:15,YELLOW_2:35;
  the carrier of Image g = rng g by YELLOW_0:def 15
    .= the carrier of Image f by WAYBEL18:9
    .= the carrier of Omega Image f by Lm1;
  hence thesis by A13,A14,A6,A12,A7,WAYBEL15:9,WAYBEL20:18,YELLOW14:11,12;
end;
