reserve Omega for non empty set,
        Sigma for SigmaField of Omega,
        Prob for Probability of Sigma,
        A for SetSequence of Sigma,
        n,n1,n2 for Nat;

theorem
( Complement A is_all_independent_wrt Prob implies
    Prob.((Partial_Intersection A).n) =
     Partial_Product(Prob*A).n ) &
( A is_all_independent_wrt Prob implies
    1-Prob.( (Partial_Union A).n ) =
     Partial_Product(Prob* Complement A).n)
proof
thus Complement A is_all_independent_wrt Prob implies
    Prob.((Partial_Intersection A).n) =
     Partial_Product(Prob*A).n
proof
 assume A1: Complement A is_all_independent_wrt Prob;
     (Partial_Intersection (Complement (Complement A))).n =
       (Partial_Intersection A).n &
      Partial_Product(Prob*(Complement (Complement A))).n =
      Partial_Product(Prob*A).n &
      Prob.((Partial_Intersection (Complement (Complement A))).n) =
       Partial_Product(Prob*(Complement (Complement A))).n by A1,Th10;
hence thesis;
end;
 assume A is_all_independent_wrt Prob; then
   Prob.( (Partial_Intersection Complement A).n ) =
      Partial_Product(Prob* Complement A).n &
   Prob.( (Partial_Intersection Complement A).n ) =
      1-Prob.( (Partial_Union A).n ) by Th10,Th8;
 hence thesis;
end;
