reserve B,C,D,C9,D9 for Category;
reserve E for Subcategory of C;

theorem
  for O being non empty Subset of the carrier of C, M being non empty
set, d,c being Function of M,O, p being PartFunc of [:M,M:],M, i being Function
of O,M st M = union{Hom(a,b) where a is Object of C,b is Object of C: a in O &
b in O} & d = (the Source of C)|M & c = (the Target of C)|M & p = (the Comp of
C)||M
  holds CatStr(#O,M,d,c,p#) is full Subcategory of C
proof
  let O be non empty Subset of the carrier of C, M be non empty set, d,c be
  Function of M,O, p be PartFunc of [:M,M:],M, i be Function of O,M;
  set H = {Hom(a,b) where a is Object of C, b is Object of C: a in O & b in O};
  assume that
A1: M = union H and
A2: d = (the Source of C)|M and
A3: c = (the Target of C)|M and
A4: p = (the Comp of C)||M;
 set B = CatStr(#O,M,d,c,p#);
A5: now
    let f be Morphism of B;
    consider X being set such that
A6: f in X and
A7: X in H by A1,TARSKI:def 4;
    ex a,b being Object of C st X = Hom(a,b) & a in O & b in O by A7;
    hence f is Morphism of C by A6;
  end;
A8: for a,b being Object of B, a9,b9 being Object of C st a = a9 & b = b9
  holds Hom(a,b) = Hom(a9,b9)
  proof
    let a,b be Object of B, a9,b9 be Object of C such that
A9: a = a9 & b = b9;
    now
      let x be object;
      thus x in Hom(a,b) implies x in Hom(a9,b9)
      proof
        assume
A10:    x in Hom(a,b);
        then reconsider f = x as Morphism of B;
        reconsider f9 = f as Morphism of C by A5;
        cod f = cod f9 by A3,FUNCT_1:49;
        then
A11:    b = cod f9 by A10,CAT_1:1;
        dom f = dom f9 by A2,FUNCT_1:49;
        then a = dom f9 by A10,CAT_1:1;
        hence thesis by A9,A11;
      end;
      assume
A12:  x in Hom(a9,b9);
      then reconsider f9 = x as Morphism of C;
      Hom(a9,b9) in H by A9;
      then reconsider f = f9 as Morphism of B by A1,A12,TARSKI:def 4;
      cod f = cod f9 by A3,FUNCT_1:49;
      then
A13:  cod f = b9 by A12,CAT_1:1;
      dom f = dom f9 by A2,FUNCT_1:49;
      then dom f = a9 by A12,CAT_1:1;
      hence x in Hom(a,b) by A9,A13;
    end;
    hence thesis by TARSKI:2;
  end;
 reconsider B as Subcategory of C by Lm2,A1,A2,A3,A4;
   B is full by A8;
  hence thesis;
end;
