
theorem Th21:
  for f being Function st dom f is subset-closed holds f is
  U-continuous iff dom f is d.union-closed & f is c=-monotone & for a, y being
set st a in dom f & y in f.a ex b being set st b is finite & b c= a & y in f.b
proof
  let f be Function such that
A1: dom f is subset-closed;
  hereby
    assume
A2: f is U-continuous;
    hence dom f is d.union-closed & f is c=-monotone;
    reconsider C = dom f as d.union-closed subset-closed set by A1,A2;
    let a, y be set;
    assume that
A3: a in dom f and
A4: y in f.a;
    reconsider A = {b where b is Subset of a: b is finite} as set;
A5: A is c=directed
    proof
      let Y be finite Subset of A;
      take union Y;
      now
        let x be set;
        assume x in Y;
        then x in A;
        then ex c being Subset of a st x = c & c is finite;
        hence x c= a;
      end;
      then
A6:   union Y c= a by ZFMISC_1:76;
      now
        let b be set;
        assume b in Y;
        then b in A;
        then ex c being Subset of a st b = c & c is finite;
        hence b is finite;
      end;
      then union Y is finite by FINSET_1:7;
      hence thesis by A6;
    end;
A7: union A = a
    proof
      thus union A c= a
      proof
        let x be object;
        assume x in union A;
        then consider b being set such that
A8:     x in b and
A9:     b in A by TARSKI:def 4;
        ex c being Subset of a st b = c & c is finite by A9;
        hence thesis by A8;
      end;
      let x be object;
      assume x in a;
      then {x} c= a by ZFMISC_1:31;
      then x in {x} & {x} in A by TARSKI:def 1;
      hence thesis by TARSKI:def 4;
    end;
A10: A c= C
    proof
      let x be object;
      assume x in A;
      then ex b being Subset of a st x = b & b is finite;
      hence thesis by A3,CLASSES1:def 1;
    end;
    then union A in C by A5,Def6;
    then f.union A = union (f.:A) by A2,A5,A10,Def10;
    then consider B being set such that
A11: y in B and
A12: B in f.:A by A4,A7,TARSKI:def 4;
    consider b being object such that
    b in dom f and
A13: b in A and
A14: B = f.b by A12,FUNCT_1:def 6;
     reconsider bb=b as set by TARSKI:1;
    take bb;
    ex c being Subset of a st b = c & c is finite by A13;
    hence bb is finite & bb c= a & y in f.bb by A11,A14;
  end;
  assume dom f is d.union-closed;
  then reconsider C = dom f as d.union-closed set;
  assume that
A15: for a,b being set st a in dom f & b in dom f & a c= b holds f.a c= f.b and
A16: for a, y being set st a in dom f & y in f.a ex b being set st b is
  finite & b c= a & y in f.b;
  C is d.union-closed;
  hence dom f is d.union-closed;
  thus f is d.union-distributive
  proof
    let A be Subset of dom f;
    assume that
A17: A is c=directed and
A18: union A in dom f;
    reconsider A9 = A as Subset of C;
    thus f.union A c= union (f.:A)
    proof
      let x be object;
      assume x in f.union A;
      then consider b being set such that
A19:  b is finite & b c= union A9 and
A20:  x in f.b by A16,A18;
      consider c being set such that
A21:  c in A and
A22:  b c= c by A17,A19,Th13;
      b in C by A1,A21,A22;
      then
A23:  f.b c= f.c by A15,A21,A22;
      f.c in f.:A by A21,FUNCT_1:def 6;
      hence thesis by A20,A23,TARSKI:def 4;
    end;
    let x be object;
    assume x in union (f.:A);
    then consider B be set such that
A24: x in B and
A25: B in f.:A by TARSKI:def 4;
    ex b being object st b in dom f & b in A & B = f.b
by A25,FUNCT_1:def 6;
    then B c= f.union A9 by A15,A18,ZFMISC_1:74;
    hence thesis by A24;
  end;
end;
