reserve X for set;
reserve CS for non empty CollStr;
reserve a,b,c for Point of CS;
reserve CLSP for CollSp;
reserve a,b,c,d,p,q,r for Point of CLSP;
reserve i,j,k for Element of NAT;
reserve CLSP for proper CollSp;
reserve a,b,c,p,q,r for Point of CLSP;
reserve P,Q for LINE of CLSP;

theorem
  P = Q or P misses Q or ex p st P /\ Q = {p}
proof
A1: (ex a be set st {a} = P /\ Q) implies ex p st P /\ Q = {p}
  proof
    given a be set such that
A2: {a} = P /\ Q;
    a in P /\ Q by A2,TARSKI:def 1;
    then a in P by XBOOLE_0:def 4;
    then reconsider p=a as Point of CLSP by Lm9;
    P /\ Q = {p} by A2;
    hence thesis;
  end;
A3: (ex a,b be set st a<>b & a in P /\ Q & b in P /\ Q) implies P = Q
  proof
    given a,b be set such that
A4: a<>b and
A5: a in P /\ Q & b in P /\ Q;
    a in P & b in P by A5,XBOOLE_0:def 4;
    then reconsider p=a, q=b as Point of CLSP by Lm9;
A6: p in Q & q in Q by A5,XBOOLE_0:def 4;
    p in P & q in P by A5,XBOOLE_0:def 4;
    hence thesis by A4,A6,Th20;
  end;
  P /\ Q = {} or ex a be set st {a} = P /\ Q or ex a,b be set st a<>b & a
  in P /\ Q & b in P /\ Q by Th1;
  hence thesis by A1,A3,XBOOLE_0:def 7;
end;
