reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (sin*tan) implies sin*tan is_differentiable_on Z & for x st x
  in Z holds ((sin*tan)`|Z).x = cos(tan.x)/(cos.x)^2
proof
  assume
A1: Z c= dom (sin*tan);
A2: for x st x in Z holds cos.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom (sin/cos) by A1,FUNCT_1:11;
    hence thesis by FDIFF_8:1;
  end;
A3: for x st x in Z holds sin*tan is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A2;
    then
A4: tan is_differentiable_in x by FDIFF_7:46;
    sin is_differentiable_in tan.x by SIN_COS:64;
    hence thesis by A4,FDIFF_2:13;
  end;
  then
A5: sin*tan is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((sin*tan)`|Z).x = cos(tan.x)/(cos.x)^2
  proof
    let x;
A6: sin is_differentiable_in tan.x by SIN_COS:64;
    assume
A7: x in Z;
    then
A8: cos.x<>0 by A2;
    then tan is_differentiable_in x by FDIFF_7:46;
    then diff(sin*tan,x) = diff(sin,tan.x)*diff(tan,x) by A6,FDIFF_2:13
      .=cos(tan.x) * diff(tan,x) by SIN_COS:64
      .=cos(tan.x) * (1/(cos.x)^2) by A8,FDIFF_7:46
      .=cos(tan.x)/(cos.x)^2;
    hence thesis by A5,A7,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
