reserve p, q for FinSequence,
  e,X for set,
  i, j, k, m, n for Nat,
  G for Graph;
reserve x,y,v,v1,v2,v3,v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for oriented Chain of G;
reserve sc for oriented simple Chain of G;
reserve x,y for set;

theorem
  vs is_oriented_vertex_seq_of c implies
  ex fc being Subset of c, fvs being Subset of vs, sc, vs1
  st Seq fc = sc & Seq fvs = vs1 & vs1 is_oriented_vertex_seq_of sc &
  vs.1 = vs1.1 & vs.len vs = vs1.len vs1
proof
  assume
A1: vs is_oriented_vertex_seq_of c;
  per cases;
  suppose
A2: c is Simple;
    reconsider fc = c as Subset of c by FINSEQ_6:152;
    reconsider fvs = vs as Subset of vs by FINSEQ_6:152;
    reconsider sc = c as oriented simple Chain of G by A2,Th19;
    take fc, fvs, sc, vs;
    thus Seq fc = sc & Seq fvs = vs by FINSEQ_3:116;
    thus vs is_oriented_vertex_seq_of sc by A1;
    thus thesis;
  end;
  suppose
A3: not c is Simple;
    defpred P[Nat] means
    ex fc being Subset of c, fvs being Subset of vs, c1, vs1
    st Seq fc = c1 & Seq fvs = vs1 & vs1 is_oriented_vertex_seq_of c1 &
    vs.1 = vs1.1 & vs.len vs = vs1.len vs1 & len c1 = $1 & not c1 is Simple;
    P[len c]
    proof
      reconsider fc = c as Subset of c by FINSEQ_6:152;
      reconsider fvs = vs as Subset of vs by FINSEQ_6:152;
      take fc, fvs, c,vs;
      thus Seq fc = c & Seq fvs = vs by FINSEQ_3:116;
      thus vs is_oriented_vertex_seq_of c by A1;
      thus vs.1 = vs.1 & vs.len vs = vs.len vs;
      thus thesis by A3;
    end;
    then
A4: ex k be Nat st P[k];
    consider k be Nat such that
A5: P[k] & for n being Nat st P[n] holds k<=n from NAT_1:sch 5(A4);
    consider fc being Subset of c, fvs being Subset of vs, c1, vs1 such that
A6: Seq fc = c1 and
A7: Seq fvs = vs1 and
A8: vs1 is_oriented_vertex_seq_of c1 and
A9: vs.1 = vs1.1 and
A10: vs.len vs = vs1.len vs1 and
A11: len c1 = k and
A12: not c1 is Simple by A5;
    consider fc1 being Subset of c1, fvs1 being Subset of vs1,
    c2, vs2 such that
A13: len c2 < len c1 and
A14: vs2 is_oriented_vertex_seq_of c2 and len vs2 < len vs1 and
A15: vs1.1 = vs2.1 and
A16: vs1.len vs1 = vs2.len vs2 and
A17: Seq fc1 = c2 and
A18: Seq fvs1 = vs2 by A8,A12,Th20;
    reconsider fc9=fc|rng((Sgm dom fc)|dom fc1) as Subset of c
      by FINSEQ_6:153;
A19: Seq fc9 = c2 by A6,A17,FINSEQ_6:154;
    reconsider fvs9=fvs|rng((Sgm dom fvs)|dom fvs1) as Subset of vs
    by FINSEQ_6:153;
A20: Seq fvs9 = vs2 by A7,A18,FINSEQ_6:154;
    now
      assume c2 is Simple oriented Chain of G;
      then reconsider sc = c2 as oriented simple Chain of G by Th19;
      take fc9,sc;
      Seq fc9 = sc by A6,A17,FINSEQ_6:154;
      hence thesis by A9,A10,A14,A15,A16,A20;
    end;
    hence thesis by A5,A9,A10,A11,A13,A14,A15,A16,A19,A20;
  end;
end;
