
theorem
  for G being strict finite commutative Group, p being Prime, m be Nat
  st card(G) = p|^m holds
  ex k be non zero Nat, a be k-element FinSequence of G,
  Inda be k-element FinSequence of NAT,
  F be associative Group-like commutative multMagma-Family of Seg k
  st (for i be Nat st i in Seg k holds ex ai be Element of G
  st ai = a.i & F.i = gr{ai} & ord(ai) = p|^(Inda.i))
  & (for i be Nat st 1 <= i & i <= k -1 holds Inda.i <= Inda.(i+1))
  & (for p,q be Element of Seg k st p <> q
  holds (the carrier of (F.p)) /\ (the carrier of (F.q)) ={1_G})
  & (for y be Element of G holds
  ex x be (the carrier of G)-valued total (Seg k) -defined Function
  st (for p be Element of Seg k holds x.p in F.p) & y = Product x)
  & for x1, x2 be (the carrier of G)-valued total (Seg k) -defined Function
  st (for p be Element of Seg k holds x1.p in F.p)
   & (for p be Element of Seg k holds x2.p in F.p)
   & Product x1 = Product x2 holds x1 = x2
  proof
    let G be strict finite commutative Group, p be Prime, m be Nat;
    assume card(G) = p|^m;
    then consider k be non zero Nat,
    a be k-element FinSequence of G, Inda be k-element FinSequence of NAT,
    F be associative Group-like commutative multMagma-Family of Seg k,
    HFG be Homomorphism of product F, G such that
    P1: (for i be Nat st i in Seg k
    holds ex ai be Element of G
    st ai = a.i & F.i = gr{ai} & ord(ai) = p|^(Inda.i))
    & (for i be Nat st 1 <= i & i <= k -1 holds Inda.i <= Inda.(i+1))
    & (for p,q be Element of (Seg k) st p <> q
    holds(the carrier of (F.p)) /\ (the carrier of (F.q)) ={1_G})
    & HFG is bijective
    & for x be (the carrier of G)-valued total (Seg k)-defined Function
    st for p be Element of (Seg k)
    holds x.p in F.p
    holds x in product F & HFG.x =Product x by LM205A;
    set I = Seg k;
    P4: for y be Element of G holds
    ex x be (the carrier of G)-valued total I -defined Function
    st (for p be Element of I holds x.p in F.p) & y = Product x
    proof
      let y be Element of G;
      y in the carrier of G;
      then y in rng HFG by P1, FUNCT_2:def 3;
      then consider x be object such that
      P2: x in the carrier of product F & y = HFG.x by FUNCT_2:11;
      reconsider x as total I-defined Function by P2, XLM18Th401;
      P3: for p be Element of I holds x.p in F.p
      proof
        let p be Element of I;
        consider R be non empty multMagma such that
        P4: R = F.p & x.p in the carrier of R by XLM18Th402, P2;
        thus x.p in (F.p) by P4;
      end;
      rng x c= the carrier of G
      proof
        let y be object;
        assume y in rng x;
        then consider i be object such that
        D2: i in dom x & y = x.i by FUNCT_1:def 3;
        reconsider i as Element of I by D2;
        consider R be non empty multMagma such that
        P4: R = F.i & x.i in the carrier of R by P2, XLM18Th402;
        reconsider i0 = i as Nat;
        consider ai be Element of G such that
        XX2: ai = a.i0 & F.i0 = gr{ai} & ord(ai) = p|^(Inda.i0) by P1;
        the carrier of (F.i) c= the carrier of G by XX2, GROUP_2:def 5;
        hence y in the carrier of G by D2, P4;
      end;
      then
      reconsider x as (the carrier of G)-valued total I -defined Function
      by RELAT_1:def 19;
      take x;
      thus thesis by P1, P2, P3;
    end;
    now
      let x1, x2 be (the carrier of G)-valued total I -defined Function;
      assume
      AS2: (for p be Element of I holds x1.p in F.p)
      & (for p be Element of I holds x2.p in F.p)
      & Product x1 = Product x2;
      x1 in product F & HFG.x1 =Product x1 by AS2, P1; then
      P4: HFG.x1 = HFG.x2 by AS2, P1;
      x1 in the carrier of product F
      & x2 in the carrier of product F by AS2, P1, STRUCT_0:def 5;
      hence x1 = x2 by P4, P1, FUNCT_2:19;
    end;
    hence thesis by P1, P4;
  end;
