 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
A c= Z & f=(exp_R*sec)(#)(sin/cos^2) & Z = dom f & f|A is continuous
implies integral(f,A)=(exp_R*sec).(upper_bound A)-(exp_R*sec).(lower_bound A)
proof
   assume
A1:A c= Z & f=(exp_R*sec)(#)(sin/cos^2) & Z = dom f & f|A is continuous;
   then
A2:f is_integrable_on A & f|A is bounded by INTEGRA5:10,11;
   Z = dom (exp_R*sec) /\ dom (sin/cos^2) by A1,VALUED_1:def 4;then
A3:Z c= dom (exp_R*sec) & Z c= dom (sin/cos^2) by XBOOLE_1:18;
then A4:exp_R*sec is_differentiable_on Z by FDIFF_9:16;
A5:for x st x in Z holds f.x=exp_R.(sec.x)*sin.x/(cos.x)^2
   proof
   let x;
   assume
A6:x in Z;
   ((exp_R*sec)(#)(sin/cos^2)).x =(exp_R*sec).x*(sin/cos^2).x by VALUED_1:5
 .=exp_R.(sec.x)*(sin/cos^2).x by A6,A3,FUNCT_1:12
 .=exp_R.(sec.x)*(sin.x/(cos^2).x) by A3,A6,RFUNCT_1:def 1
 .=exp_R.(sec.x)*(sin.x/(cos.x)^2) by VALUED_1:11
 .=exp_R.(sec.x)*sin.x/(cos.x)^2 ;
   hence thesis by A1;
   end;
A7:for x being Element of REAL
   st x in dom ((exp_R*sec)`|Z) holds ((exp_R*sec)`|Z).x=f.x
 proof
   let x be Element of REAL;
   assume x in dom ((exp_R*sec)`|Z);then
A8:x in Z by A4,FDIFF_1:def 7;then
  ((exp_R*sec)`|Z).x=exp_R.(sec.x)*sin.x/(cos.x)^2 by A3,FDIFF_9:16
                   .=f.x by A5,A8;
  hence thesis;
  end;
  dom ((exp_R*sec)`|Z)=dom f by A1,A4,FDIFF_1:def 7;
  then ((exp_R*sec)`|Z)= f by A7,PARTFUN1:5;
  hence thesis by A1,A2,A4,INTEGRA5:13;
end;
